Usa la API de Translation con el SDK de ABAP para Google Cloud

1. Introducción

En este codelab, se proporcionan pasos para llamar a los métodos de la API de Translation V3 (avanzada) con el SDK de ABAP para Google Cloud. En este codelab, veremos cómo traducir un texto, detectar su idioma y enumerar los idiomas compatibles con la API de Translation V3.

En este codelab, se usan los siguientes servicios de Google Cloud:

• Compute Engine
• Servicios de red
• Cloud Shell
• API de Cloud Translation V3

Requisitos previos

• Asegúrate de tener acceso a un sistema SAP con el SDK de ABAP para Google Cloud instalado.
• Puedes consultar el codelab " Install ABAP Platform Testing 1909 on Google Cloud Platform and Install ABAP SDK (Instala la prueba 1909 de la plataforma ABAP en Google Cloud Platform e instala el SDK de ABAP). para configurar un sistema nuevo.

Qué compilarás

Crearás los siguientes programas en tu sistema SAP con el SDK de ABAP para Google Cloud:

• Traduce texto a varios idiomas con la API de Cloud Translation V3 de Google
• Detecta el idioma del texto fuente con la API de Google Cloud Translation V3
• Enumerar los idiomas admitidos en la API de Google Cloud Translation V3

2. Requisitos

• Un navegador, como Chrome o Firefox
• Tener un proyecto de Google Cloud con facturación habilitada o crear una cuenta de prueba gratuita de 90 días para Google Cloud Platform
• La GUI de SAP (Windows o Java) instalada en tu sistema Si la GUI de SAP ya está instalada en tu máquina, conéctate a SAP con la dirección IP externa de la VM como la IP del servidor de aplicaciones. Si utilizas una Mac, también puedes instalar la GUI de SAP para Java disponible en este vínculo.

3. Antes de comenzar

• Asegúrate de tener acceso a un sistema SAP con el SDK de ABAP para Google Cloud instalado.
• Puedes consultar el codelab " Install ABAP Platform Testing 1909 on Google Cloud Platform and Install ABAP SDK (Instala la prueba 1909 de la plataforma ABAP en Google Cloud Platform e instala el SDK de ABAP). para configurar un sistema nuevo.
• En la consola de Google Cloud, en la página del selector de proyectos, selecciona o crea un proyecto de Google Cloud (por ejemplo: abap-sdk-poc).
• Asegúrate de que la facturación esté habilitada para tu proyecto de Cloud. Obtén información sobre cómo verificar si la facturación está habilitada en un proyecto. Omite este paso si usas la cuenta de prueba gratuita de 90 días.
• Usarás Cloud Shell, un entorno de línea de comandos que se ejecuta en Google Cloud. En la consola de Cloud, haz clic en Activar Cloud Shell en la esquina superior derecha:

• Ejecuta los siguientes comandos para autenticar tu cuenta y establece el proyecto predeterminado como abap-sdk-poc. Se usa la zona us-west4-b como ejemplo. Si es necesario, cambia el proyecto y la zona en los siguientes comandos según tus preferencias.

gcloud auth login
gcloud config set project abap-sdk-poc
gcloud config set compute/zone us-west4-b

• Debes tener acceso a un sistema SAP con el SDK de ABAP para Google Cloud instalado.
• Debes completar el codelab 1 (Instala la prueba 1909 de la plataforma ABAP en Google Cloud Platform e instala el SDK de ABAP para Google Cloud) y el codelab 2 (Cómo configurar la autenticación del SDK de ABAP con tokens para SAP alojado en la VM de Compute Engine) antes de continuar con este codelab.
• Si completaste el codelab 1 y el 2, se te habría proporcionado un sistema ABAP de prueba 1909 de la plataforma en Google Cloud, junto con la configuración necesaria de autenticación y conectividad.
• Si no completaste el codelab 1 y el codelab 2, no tendrás toda la infraestructura y la conectividad necesarias para realizar los pasos que se proporcionan en este codelab. Por lo tanto, debes completar el codelab 1 y el 2 antes de continuar con este codelab.

4. Habilita la API de Cloud Translation V3 en tu proyecto de Google Cloud

1. Ejecuta el siguiente comando en Cloud Shell para habilitar la API de Cloud Translation en tu proyecto de Google Cloud:

gcloud services enable translate.googleapis.com

Si la ejecución es exitosa, deberías ver un mensaje como el siguiente:

Ahora deberías tener habilitada la API de Cloud Translation en tu proyecto de Google Cloud.

5. Crea una cuenta de servicio con el rol Usuario de Cloud Translation

Para crear una cuenta de servicio con el rol necesario, sigue estos pasos:

1. Ejecuta el siguiente comando en la terminal de Cloud Shell:

gcloud iam service-accounts create abap-sdk-translation-tester \
--display-name="Service Account for Translation"

Nota: Si el comando anterior se ejecuta correctamente, deberías recibir la siguiente respuesta:

Se creó la cuenta de servicio [abap-sdk-translation-tester] .

2. Ahora agrega los roles necesarios a la cuenta de servicio creada en el paso anterior.

gcloud projects add-iam-policy-binding abap-sdk-poc\
--member='serviceAccount:[e-mail]' \
--role='roles/cloudtranslate.user'

El comando anterior usa abap-sdk-poc como nombre de la plantilla para el proyecto de Google Cloud. Reemplázalo con tu ID del proyecto.

3. Para verificar que se agregó el rol, ve a la página IAM. La cuenta de servicio que creaste debería aparecer junto con el rol que se le asignó, como se muestra a continuación:

6. Crear configuración de clave de cliente

Ahora que estableciste los requisitos previos en Google Cloud, podemos avanzar con la configuración en el lado de SAP.

En la configuración relacionada con la autenticación y la conectividad, el SDK de ABAP para Google Cloud usa la tabla /GOOG/CLIENT_KEY

Para mantener la configuración en la tabla /GOOG/CLIENT_KEY, realiza los siguientes pasos:

1. En la GUI de SAP, ingresa el código de transacción SPRO.
2. Haz clic en IMG de referencia de SAP.
3. Haz clic en SDK de ABAP para Google Cloud > Configuración básica > Configura la clave de cliente.
4. Mantén los siguientes valores en los campos:

Campo	Valor
Nombre de la clave de Google Cloud	TEST_TRANSLATION
Nombre de la cuenta de servicio de Google Cloud	[e-mail]
Permiso de Google Cloud	https://www.googleapis.com/auth/cloud-platform
ID del proyecto	abap-sdk-poc
Clase de autorización	/GOOG/CL_AUTH_GOOGLE

Deja todos los demás campos en blanco.

NOTA: La configuración de la tabla /GOOG/SERVIC_MAP es opcional y se puede omitir en este caso.

7. Crea un informe Z para llamar a la API de Cloud Translation V3 y traducir un texto

1. Accede a tu sistema SAP.
2. Ve al código de transacción SE38 y crea un programa de informes con el nombre ZDEMO_TRANSLATE_TEXT..
3. En la ventana emergente que se abre, ingresa los detalles como se muestra a continuación y haz clic en Guardar.

En la siguiente ventana emergente, selecciona Objeto local o Proporciona un nombre de paquete según tu elección.

4. En el Editor de ABAP, agrega el siguiente código:

DATA lo_translate TYPE REF TO /goog/cl_translation_v3.
DATA ls_input TYPE /goog/cl_translation_v3=>ty_050.

TRY.
    lo_translate = NEW #( iv_key_name = 'TEST_TRANSLATION').

    ls_input = VALUE #(  mime_type = 'text/plain'
                         source_language_code = 'en-US'
                         target_language_code = 'es-ES'
                         contents =  VALUE #( ( |Sun is our nearest star| ) ) ).

    lo_translate->translate_text_projects(
      EXPORTING
        iv_p_projects_id = CONV #( lo_translate->gv_project_id )
        is_input         = ls_input
      IMPORTING
        es_output        =  DATA(ls_output)
        ev_ret_code      =  DATA(lv_ret_code)
        ev_err_text      =  DATA(lv_err_text)
        es_err_resp      =  DATA(lv_err_resp)
    ).
    IF lo_translate->is_success( lv_ret_code ) = abap_true.
      cl_demo_output=>new(
      )->begin_section( 'API Call Successful:'
      )->write_text( 'Translated Text:'
      )->write_data( ls_output-translations[ 1 ]-translated_text
      )->display( ).
    ELSE.
      cl_demo_output=>new(
      )->begin_section( 'API Call Unsuccessful:'
      )->write_text( 'Error Message:'
      )->write_text( lv_err_text
      )->display( ).
    ENDIF.
  CATCH /goog/cx_sdk INTO DATA(lo_sdk_excp).
    DATA(lv_error) = lo_sdk_excp->get_text( ).
    cl_demo_output=>new(
     )->begin_section( 'Exception Occured:'
     )->write_text( lv_error
     )->display( ).
ENDTRY.

5. Guarde y active el informe.
6. Ejecuta el informe (F8).

Si la ejecución es exitosa, deberías ver el resultado del informe como se muestra a continuación:

8. Crear un informe Z para llamar a la API de Cloud Translation V3 y detectar el idioma

1. Accede a tu sistema SAP.
2. Ve al código de transacción SE38 y crea un programa de informes con el nombre ZDEMO_DETECT_LANGUAGE..
3. En la ventana emergente que se abre, proporciona los detalles como se muestra a continuación y haz clic en Guardar:

En la siguiente ventana emergente, selecciona Objeto local o Proporciona un nombre de paquete según tu elección.

4. En el Editor de ABAP, agrega el siguiente código:

DATA lo_translate TYPE REF TO /goog/cl_translation_v3.
DATA ls_input TYPE /goog/cl_translation_v3=>ty_009.

TRY.
    lo_translate = NEW #( iv_key_name = 'TEST_TRANSLATION').

    ls_input = VALUE #(  mime_type = |text/plain|
                         content =  |La luce viaggia più veloce del suono| ).

    lo_translate->detect_language_projects(
      EXPORTING
        iv_p_projects_id = CONV #( lo_translate->gv_project_id )
        is_input         = ls_input
      IMPORTING
        es_output        =  DATA(ls_output)
        ev_ret_code      =  DATA(lv_ret_code)
        ev_err_text      =  DATA(lv_err_text)
        es_err_resp      =  DATA(lv_err_resp)
    ).
    IF lo_translate->is_success( lv_ret_code ) = abap_true.
      cl_demo_output=>new(
      )->begin_section( 'API Call Successful:'
      )->write_text( 'Detected Language:'
      )->write_data( ls_output-languages[ 1 ]-language_code
      )->display( ).
    ELSE.
      cl_demo_output=>new(
      )->begin_section( 'API Call Unsuccessful:'
      )->write_text( 'Error Message:'
      )->write_text( lv_err_text
      )->display( ).
    ENDIF.
  CATCH /goog/cx_sdk INTO DATA(lo_sdk_excp).
    DATA(lv_error) = lo_sdk_excp->get_text( ).
    cl_demo_output=>new(
     )->begin_section( 'Exception Occured:'
     )->write_text( lv_error
     )->display( ).
ENDTRY.

5. Guarde y active el informe.
6. Ejecuta el informe (F8).

Si la ejecución es exitosa, deberías ver el resultado del informe como se muestra a continuación:

9. Crea un informe Z para llamar al método GET_SUPPORTED_LANGUAGES

1. Accede a tu sistema SAP.
2. Ve al código de transacción SE38 y crea un programa de informes con el nombre ZDEMO_GET_LANGUAGES..
3. En la ventana emergente que se abre, proporciona los detalles como se muestra a continuación y haz clic en Guardar.

En la siguiente ventana emergente, selecciona Objeto local o Proporciona un nombre de paquete según tu elección.

4. En el Editor de ABAP, agrega el siguiente código:

DATA lo_translate TYPE REF TO /goog/cl_translation_v3.

TRY.
    lo_translate = NEW #( iv_key_name = 'TEST_TRANSLATION').

    lo_translate->get_supported_languages_pro(
      EXPORTING
        iv_q_displaylanguagecode = 'en-US'
        iv_p_projects_id         =  CONV #( lo_translate->gv_project_id )
      IMPORTING
        es_output        =  DATA(ls_output)
        ev_ret_code      =  DATA(lv_ret_code)
        ev_err_text      =  DATA(lv_err_text)
        es_err_resp      =  DATA(lv_err_resp)
    ).

    IF lo_translate->is_success( lv_ret_code ) = abap_true.
      cl_demo_output=>new(
      )->begin_section( 'API Call Successful:'
      )->write_text( 'Supported Languages:'
      )->write_data( ls_output-languages
      )->display( ).
    ELSE.
      cl_demo_output=>new(
      )->begin_section( 'API Call Unsuccessful:'
      )->write_text( 'Error Message:'
      )->write_text( lv_err_text
      )->display( ).
    ENDIF.
  CATCH /goog/cx_sdk INTO DATA(lo_sdk_excp).
    DATA(lv_error) = lo_sdk_excp->get_text( ).
    cl_demo_output=>new(
     )->begin_section( 'Exception Occured:'
     )->write_text( lv_error
     )->display( ).
ENDTRY.

5. Guarde y active el informe.
6. Ejecuta el informe (F8).

Si la ejecución es exitosa, deberías ver el resultado del informe como se muestra a continuación:

10. Felicitaciones

¡Felicitaciones! Completaste correctamente el curso “Usa la API de Translation con el SDK de ABAP para Google Cloud” en este codelab.

La API de Cloud Translation V3, también conocida como API de Cloud Translation Advanced, tiene muchas funciones, entre las que se incluyen las siguientes:

• Traducción con modelos personalizados
• Traducir con glosarios
• Compatibilidad con transliteración
• Traducción de documentos

Ahora puedes continuar con los siguientes codelabs para continuar con tu recorrido de aprendizaje sobre el uso del SDK de ABAP para Google Cloud y acceder a varios servicios de Google Cloud.

• Envía un evento a Pub/Sub
• Recibe un evento de Cloud Pub/Sub
• Sube un objeto grande a un bucket de Cloud Storage mediante la fragmentación
• Usa la API de DLP para ocultar PII
• Llama a BigQuery ML desde ABAP

11. Limpia

Si no quieres continuar con los codelabs adicionales relacionados con el SDK de ABAP para Google Cloud, continúa con la limpieza.

Borra el proyecto

Precaución: Borrar un proyecto tiene las siguientes consecuencias:

• Se borra todo en el proyecto. Si usaste un proyecto existente para las tareas de este documento, cuando lo borres, también borrarás cualquier otro trabajo que hayas realizado en el proyecto.
• Se pierden los ID personalizados de proyectos. Cuando creaste este proyecto, es posible que hayas creado un ID del proyecto personalizado que desees utilizar en el futuro. Para conservar las URL que utilizan el ID del proyecto, como una URL de appspot.com, borra los recursos seleccionados dentro del proyecto en lugar de borrar todo el proyecto.

Si planeas explorar varias arquitecturas, instructivos o guías de inicio rápido, la reutilización de proyectos puede ayudarte a evitar exceder los límites de las cuotas del proyecto.

• Borra el proyecto de Google Cloud:

gcloud projects delete abap-sdk-poc

Borra recursos individuales

1. Borra la instancia de procesamiento:

gcloud compute instances delete abap-trial-docker

2. Borra las reglas de firewall:

gcloud compute firewall-rules delete sapmachine

3. Borra la cuenta de servicio:

gcloud iam service-accounts delete \
    [e-mail]