Connessione a CloudSQL tramite Private Service Connect (Terraform)

1. Panoramica

Esistono diverse opzioni per connettersi a un'istanza privata Cloud SQL da un altro progetto o VPC. Private Service Connect (PSC) consente ai producer di servizi di esporre i propri servizi tramite collegamenti di servizio. Questi collegamenti di servizio possono essere utilizzati dai consumer per creare endpoint PSC e/o backend PSC nel proprio ambiente e connettersi a questi servizi producer tramite un IP privato specificato.

Cloud SQL è in grado di utilizzare il collegamento al servizio PSC per consentire la connessione privata. In questo lab puoi configurare e testare l'opzione.

Nota:questa soluzione presenta alcune limitazioni, che puoi consultare nella sezione Limitazione di Private Service Connect della documentazione.

In questo lab, creerai un'architettura semplice che illustra l'utilizzo dell'accesso all'endpoint PSC con CloudSQL.

Figura 1.

Per questo lab, avrai bisogno di due progetti o di VPC separati nello stesso progetto.

Nota:l'accesso globale può essere abilitato sull'endpoint PSC per renderlo disponibile da altre regioni.

Obiettivi

In questo lab imparerai a:

• Crea un'istanza Cloud SQL con il collegamento a un servizio PSC.
• Crea un indirizzo IP statico
• Crea un endpoint PSC nel VPC consumer per connetterti al database CloudSQL
• Verifica l'accesso al database SQL da una VM di test nella rete consumer tramite l'IP dell'endpoint PSC.

Nota:questo design può essere utilizzato da più consumatori. Scopri di più sulla multi-tenancy di Private Service Connect.

2. Configurazione e requisiti

Configurazione dell'ambiente autonomo

1. Accedi alla console Google Cloud e crea un nuovo progetto o riutilizzane uno esistente. Se non hai ancora un account Gmail o Google Workspace, devi crearne uno.

• Il nome del progetto è il nome visualizzato per i partecipanti a questo progetto. È una stringa di caratteri non utilizzata dalle API di Google. Puoi sempre aggiornarlo.
• L'ID progetto è univoco in tutti i progetti Google Cloud ed è immutabile (non può essere modificato dopo l'impostazione). La console Cloud genera automaticamente una stringa univoca, di solito non ti interessa di cosa si tratta. Nella maggior parte dei codelab, dovrai fare riferimento all'ID progetto (in genere identificato come PROJECT_ID). Se l'ID generato non ti piace, puoi generarne un altro casuale. In alternativa, puoi provare a crearne uno e vedere se è disponibile. Non può essere modificato dopo questo passaggio e rimane per tutta la durata del progetto.
• Per tua informazione, esiste un terzo valore, un numero di progetto, utilizzato da alcune API. Scopri di più su tutti e tre questi valori nella documentazione.

Attenzione:un ID progetto è univoco a livello globale e non può essere utilizzato da altri dopo che lo hai selezionato. Sei l'unico utente di questo ID. Anche se un progetto viene eliminato, l'ID non può essere riutilizzato

Nota:se utilizzi un account Gmail, puoi lasciare la posizione predefinita impostata su Nessuna organizzazione. Se utilizzi un account Google Workspace, scegli una posizione adatta alla tua organizzazione.

2. Successivamente, devi abilitare la fatturazione in Cloud Console per utilizzare le risorse/API Cloud. Completare questo codelab non costa molto, se non nulla. Per arrestare le risorse ed evitare addebiti oltre a quelli previsti in questo tutorial, puoi eliminare le risorse che hai creato o il progetto. I nuovi utenti di Google Cloud possono beneficiare del programma prova senza costi di 300$.

Avvia Cloud Shell

Sebbene Google Cloud possa essere gestito da remoto dal tuo laptop, in questo codelab utilizzerai Google Cloud Shell, un ambiente a riga di comando in esecuzione nel cloud.

Nella console Google Cloud, fai clic sull'icona di Cloud Shell nella barra degli strumenti in alto a destra:

Bastano pochi istanti per eseguire il provisioning e connettersi all'ambiente. Al termine, dovresti vedere un risultato simile a questo:

Questa macchina virtuale è caricata con tutti gli strumenti per sviluppatori di cui avrai bisogno. Offre una home directory permanente da 5 GB e viene eseguita su Google Cloud, migliorando notevolmente le prestazioni e l'autenticazione della rete. Tutto il lavoro in questo codelab può essere svolto all'interno di un browser. Non devi installare nulla.

3. Attività 1: Configura l'ambiente per il progetto di database con (Terraform)

Tieni presente che alcune risorse che attivi comportano dei costi. Per ridurre i costi, assicurati che le risorse vengano eliminate al termine del lab. Ti consigliamo di controllare la fatturazione e assicurarti che l'esercizio sia accettabile per te.

Nel progetto di database,creeremo un VPC personalizzato con regole firewall e subnet. Apri la console Cloud e seleziona il progetto che utilizzerai per il database.

1. Apri Cloud Shell in alto a destra nella console, assicurati di visualizzare l'ID progetto del progetto di database in Cloud Shell e conferma le richieste per consentire l'accesso.
2. Crea una cartella denominata terraform-db e spostati al suo interno

mkdir terraform-db  && cd terraform-db

3. Crea un file main.tf, variable.tf e database.tf.

touch main.tf variable.tf database.tf 

4. Passa alla visualizzazione dell'editor di Cloud Shell. Seleziona Editor e assicurati di consentire tutti i prompt necessari per caricare l'interfaccia.
5. Una volta caricato, vai a File > Apri cartella e vai a /home/your-user-name/terraform-db e seleziona Ok per aprire la cartella nell'editor.
6. Seleziona il file variable.tf e aggiungi quanto segue. Sostituisci il testo your-database-project-id-here con l'ID effettivo del progetto di database tra virgolette. Sostituisci il testo your-consumer-project-id-here con l'ID del tuo progetto consumer effettivo tra virgolette.

variable "project_id" {
  type = string
  default = "your-database-project-id-here"
}

variable "project_id_consumer" {
  type = set(string)
  default = ["your-consumer-project-id-here"]
}

variable "network_id" {
  type = string
  default = "database-net"
}

variable "region_id" {
  type = string
  default = "us-east1"
}

variable "db_password" {
  type = string
  default = "cloudsql24"
}

7. A questo punto, apri il file main.tf. Aggiungeremo del codice Terraform per eseguire varie azioni, come spiegato di seguito.

Abilita API	resource "google_project_service" "default"
Crea VPC	resource "google_compute_network" "default"
Aggiungere regole firewall	resource "google_compute_firewall" "allow_icmp"

8. Copia e incolla quanto segue nel file main .tf.

resource "google_project_service" "default" {
  for_each = toset([
    "compute.googleapis.com",
    "sqladmin.googleapis.com"
  ])

  service            = each.value
  disable_on_destroy = false
}

resource "google_compute_network" "default" {
  project                 = var.project_id
  name                    = var.network_id
  auto_create_subnetworks = true
  mtu                     = 1460
  routing_mode            = "GLOBAL"
}

resource "google_compute_firewall" "allow_icmp" {
  name    = "allow-icmp-${google_compute_network.default.name}"
  network = google_compute_network.default.id
  project = var.project_id

  allow {
    protocol = "icmp"
  }

  source_ranges = ["0.0.0.0/0"]
  target_tags   = ["allow-icmp"]
}

resource "google_compute_firewall" "allow_ssh" {
  name    = "allow-ssh-${google_compute_network.default.name}"
  network = google_compute_network.default.id
  project = var.project_id

  allow {
    protocol = "tcp"
    ports    = ["22"]
  }

  source_ranges = ["0.0.0.0/0"]
  target_tags   = ["allow-ssh"]
}

resource "google_compute_firewall" "allow_sql" {
  name    = "allow-sql-${google_compute_network.default.name}"
  network = google_compute_network.default.id
  project = var.project_id

  allow {
    protocol = "tcp"
    ports    = ["3306"]
  }

  source_ranges = ["0.0.0.0/0"]
 }

resource "google_compute_firewall" "allow_internal" {
  name    = "allow-internal-${google_compute_network.default.name}"
  network = google_compute_network.default.id
  project = var.project_id

  allow {
    protocol = "icmp"
    }


  allow {
    protocol = "tcp"
    ports    = ["0-65535"]
  }
  allow {
    protocol = "udp"
    ports    = ["0-65535"]
  }

  source_ranges = ["10.128.0.0/9"]
 }

9. Torna al terminale Cloud Shell, assicurati di trovarti nella directory terraform-db cd terraform-db ed esegui questi comandi:

terraform init

Inizializza la directory di lavoro. Questo passaggio scarica i provider richiesti per la configurazione specificata.

terraform plan

Genera un piano di esecuzione, che mostra le azioni che Terraform eseguirà per eseguire il deployment dell'infrastruttura.

10. Ora, per creare le risorse, esegui il comando terraform apply e digita yes per eseguire.

Verifica la configurazione:

Controlla l'ambiente per

1 VPC in modalità automatica denominato database-net

Firewall-rules

4. Attività 2: Crea un'istanza Cloud SQL con collegamento PSC (Terraform)

Utilizziamo Terraform per creare un'istanza Cloud SQL con l'opzione PSC per consentire la connettività. Completa questa configurazione nel progetto di database.

1. Passa alla visualizzazione dell'editor di Cloud Shell. Assicurati di trovarti nella cartella terraform-db. Seleziona il file database.tf e aggiungi quanto segue.

resource "google_sql_database_instance" "default" {
  name             = "psc-sql-db"
  region           = var.region_id
  database_version = "MYSQL_8_0"
  settings {
    tier              = "db-f1-micro"
    availability_type = "REGIONAL"
    backup_configuration {
      enabled            = true
      binary_log_enabled = true
    }
    ip_configuration {
      psc_config {
        psc_enabled               = true
        allowed_consumer_projects = var.project_id_consumer
      }
      ipv4_enabled = false
    }
  }
  deletion_protection = false 
}

resource "google_sql_user" "users" {
  name     = "testsql"
  instance = google_sql_database_instance.default.name
  password = var.db_password 
}

2. Torna al terminale Cloud Shell e assicurati di trovarti nella directory terraform-db. Ora, per creare le risorse, esegui il comando terraform apply e digita yes per eseguire. La creazione dell'istanza Cloud SQL con il collegamento PSC può richiedere fino a 5 minuti o più.

Verificare il database

3. Al termine, vai a SQL nella console e seleziona l'istanza di database psc-sql-db appena creata.
4. Sul lato sinistro, espandi il riquadro delle opzioni SQL e seleziona Connessioni.
5. Nella scheda Riepilogo puoi visualizzare le informazioni sulla connessione.
6. Copia l'indirizzo dell'allegato di servizio e salvalo in un punto qualsiasi del sistema.
7. Ti servirà per completare il passaggio 8 dell'attività 3.

8. Sul lato sinistro, espandi il riquadro delle opzioni SQL e seleziona Utenti.
9. Dovresti visualizzare un utente chiamato testsql con la password cloudsql24 (che verrà utilizzata per accedere al database in un secondo momento)

Verifica la configurazione:

1 istanza di database SQL con collegamento al servizio

Un utente chiamato testsql e password cloudsql24

5. Attività 3: Configura l'ambiente per il progetto consumer (Terraform)

Nel progetto consumer,creeremo un VPC personalizzato con regole firewall e subnet. Apri la console Cloud e seleziona il progetto che utilizzerai.

1. Nella parte superiore della console, a destra, accanto all'icona di Google Cloud, fai clic sul menu a discesa e seleziona la scheda Tutti.

2. Seleziona l'ID del tuo progetto consumer tra quelli elencati per continuare.
3. Apri Cloud Shell, che si trova in alto a destra nella console, assicurati di visualizzare l'ID progetto consumer in Cloud Shell e conferma le richieste di autorizzazione dell'accesso.
4. Crea una cartella denominata terraform-consumer e spostati nella cartella

mkdir terraform-consumer  && cd terraform-consumer

5. Crea un file main.tf, variable.tf e psc.tf.

touch main.tf variable.tf psc.tf 

6. Passa alla visualizzazione dell'editor Cloud Shell per l'ID progetto consumer. Seleziona Editor e assicurati di consentire tutti i prompt necessari per caricare l'interfaccia.
7. Una volta caricato, vai a File > Apri cartella e vai a /home/your-user-name/terraform-consumer e seleziona Ok per aprire la cartella nell'editor.
8. Seleziona il file variable.tf e aggiungi quanto segue. Sostituisci il testo your-consumer-project-id-here con il tuo ID progetto consumer effettivo tra virgolette. Sostituisci il testo your-psc-attachment-id-here con l'indirizzo dell'allegato psc tra virgolette. Questo è l'ID che hai copiato nella sezione 2-5 dell'attività 2

variable "project_id" {
  type = string
  default = "your-consumer-project-id-here"
}

variable "psc_attachment_id" {
  type = string
  default = "your-psc-attachment-id-here"
}

variable "network_id" {
  type = string
  default = "psc-endpoint-net"
}

variable "region_id" {
  type = string
  default = "us-east1"
}

variable "region_id2" {
  type = string
  default = "us-central1"
}

9. A questo punto, apri il file main.tf. Aggiungeremo del codice Terraform per eseguire varie azioni, come spiegato di seguito.

Abilita API	resource "google_project_service"
Crea VPC	resource "google_compute_network"
Crea gateway NAT	resource "google_compute_router" resource "google_compute_router_nat"
Aggiungere regole firewall	resource "google_compute_firewall"

10. Copia e incolla quanto segue nel file main .tf.

resource "google_project_service" "default" {
  for_each = toset([
    "compute.googleapis.com",
    "cloudresourcemanager.googleapis.com"
  ])

  service            = each.value
  disable_on_destroy = false
}

resource "google_compute_network" "default" {
  project                 = var.project_id
  name                    = var.network_id
  auto_create_subnetworks = false
  mtu                     = 1460
  routing_mode            = "GLOBAL"
}

resource "google_compute_subnetwork" "vm_subnet" {
  name          = "vm-subnet"
  ip_cidr_range = "192.168.50.0/24"
  region        = var.region_id2
  network       = google_compute_network.default.name
  project       = var.project_id
}

resource "google_compute_subnetwork" "psc_subnet" {
  name          = "psc-subnet"
  ip_cidr_range = "192.168.90.0/24"
  region        = var.region_id
  network       = google_compute_network.default.name
  project       = var.project_id
}

resource "google_compute_router" "default" {
  name    = "outbound-nat"
  region  = var.region_id2
  network = google_compute_network.default.id

 bgp {
  asn = 64514
  }
}

resource "google_compute_router_nat" "default" {
  name = "outbound-nat-gw"
  router = google_compute_router.default.name
  region = google_compute_router.default.region
  nat_ip_allocate_option = "AUTO_ONLY"
  source_subnetwork_ip_ranges_to_nat = "ALL_SUBNETWORKS_ALL_IP_RANGES"

  log_config {
    enable = true
    filter = "ERRORS_ONLY"
  }
}

resource "google_compute_firewall" "allow_icmp" {
  name    = "allow-icmp-${google_compute_network.default.name}"
  network = google_compute_network.default.id
  project = var.project_id

  allow {
    protocol = "icmp"
  }

  source_ranges = ["0.0.0.0/0"]
  
}

resource "google_compute_firewall" "allow_ssh" {
  name    = "allow-ssh-${google_compute_network.default.name}"
  network = google_compute_network.default.id
  project = var.project_id

  allow {
    protocol = "tcp"
    ports    = ["22"]
  }

  source_ranges = ["0.0.0.0/0"]
  target_tags   = ["allow-ssh"]
}


resource "google_compute_firewall" "allow_internal" {
  name    = "allow-internal-${google_compute_network.default.name}"
  network = google_compute_network.default.id
  project = var.project_id

  allow {
    protocol = "icmp"
    }


  allow {
    protocol = "tcp"
    ports    = ["0-65535"]
  }
  allow {
    protocol = "udp"
    ports    = ["0-65535"]
  }

  source_ranges = ["192.168.0.0/16"]
 }

11. Torna al terminale Cloud Shell, assicurati di trovarti nella directory terraform-consumer cd terraform-consumer nel progetto consumer ed esegui questi comandi:

terraform init

Inizializza la directory di lavoro. Questo passaggio scarica i provider richiesti per la configurazione specificata.

terraform plan

Genera un piano di esecuzione, che mostra le azioni che Terraform eseguirà per eseguire il deployment dell'infrastruttura.

12. Ora, per creare le risorse, esegui il comando terraform apply e digita yes per eseguire.

Verifica la configurazione:

Controlla l'ambiente per

Una rete VPC personalizzata denominata psc-endpoint-net

Gateway NAT con regole firewall

6. Attività 4: Crea l'endpoint PSC per l'allegato SQL DB nel progetto consumer e nella VM di test (Terraform)

Completa questa configurazione nel progetto consumer.

1. Torna all'editor di Cloud Shell, apri la directory terraform-consumer e seleziona il file psc.tf. Aggiungi il seguente codice Terraform al file. Vengono creati un IP interno statico, un endpoint PSC e una VM di test con MariaDB installato.

resource "google_compute_address" "default" {
  name = "psc-ip"
  region = var.region_id
  address_type = "INTERNAL"
  subnetwork = google_compute_subnetwork.psc_subnet.name
  address = "192.168.90.100" 
}

resource "google_compute_forwarding_rule" "default" {
  name = "psc-sql-endpoint"
  region = var.region_id
  network = google_compute_network.default.name
  ip_address = google_compute_address.default.self_link
  load_balancing_scheme = ""
  target = var.psc_attachment_id
}


resource "google_compute_instance" "sql_test_vm" {
  name         = "sql-test-vm"
  machine_type = "e2-medium"
  zone         = "${var.region_id2}-b"
  project      = var.project_id

  boot_disk {
    initialize_params {
      image = "debian-cloud/debian-11"
    }
  }

  network_interface {
    subnetwork = google_compute_subnetwork.vm_subnet.name
  }

  # No external IP address
  network_performance_config {
    total_egress_bandwidth_tier = "DEFAULT"
  }

  tags = ["allow-icmp", "allow-ssh", "allow-internal", "allow-health-check"]

  # Install MariaDB at startup
  metadata_startup_script = <<EOF
#!/bin/bash
apt-get update
apt-get install -y mariadb-server
systemctl enable mariadb
EOF
}

2. Torna al terminale Cloud Shell, assicurati di trovarti nella directory terraform-consumer cd terraform-consumer nel progetto consumer ed esegui questi comandi:

terraform plan

Genera un piano di esecuzione, che mostra le azioni che Terraform eseguirà per eseguire il deployment dell'infrastruttura.

3. Ora, per creare le risorse, esegui il comando terraform apply e digita yes per eseguire
4. Poiché la nostra VM e il nostro endpoint si trovano in regioni diverse, dobbiamo abilitare l' accesso globale all'endpoint PSC. Lo facciamo tramite la console
5. Nella console del progetto consumer, vai a Private Service Connect. Nella scheda Endpoint connesso, cerca la sezione Endpoint e seleziona psc-sql-endpoint.
6. Ora seleziona MODIFICA,quindi fai clic sulla casella di controllo accanto a Attiva accesso globale e all'opzione Salva.
7. Continua con il passaggio successivo per verificare la connettività

7. Attività 5: Verifica la connettività dell'endpoint dalla VM tramite l'indirizzo IP PSC

Completa questa operazione nel progetto consumer

1. Vai a Istanza VM. Seleziona sql-test-vm
2. Seleziona l'opzione SSH per connetterti alla VM.
3. Connettiti al database tramite l'endpoint con quanto segue:

mysql --host=192.168.90.100 --user=testsql --password=cloudsql24

4. Una volta stabilita la connessione, crea un database con il seguente psc-sql-db.

CREATE DATABASE remotesqldb;

5. Al termine, digita exit per uscire dalla connessione.

8. Attività 6: Verifica la voce del database

Completa questa verifica nel progetto di database

1. Nella parte superiore della console, a destra, accanto all'icona di Google Cloud, fai clic sul menu a discesa e seleziona la scheda Tutti.

2. Per continuare, seleziona l'ID progetto del database tra i progetti elencati.
3. Vai a SQL, seleziona il database psc-sql-db, espandi le opzioni SQL e seleziona Database. Dovresti vedere il database appena creato chiamato remotesqldb dalla VM del progetto consumer**.**

Nota:puoi anche connetterti utilizzando un nome DNS. Scopri di più sulla configurazione del DNS qui: Configura una zona gestita DNS e un record DNS.

9. Esegui la pulizia

Assicurati di eseguire la pulizia per evitare addebiti non necessari.

Completa questa operazione nel progetto Database

1. Seleziona l'ID progetto del database
2. Vai a Cloud Shell e assicurati di visualizzare l'ID progetto del database
3. Vai alla directory terraform-db cd terraform-db ed esegui il comando seguente terraform destroy e digita yes tutte le risorse che hai creato nel progetto db con Terraform verranno rimosse.

Completa questa operazione nel progetto consumer

1. Seleziona l'ID progetto consumer
2. Vai a Cloud Shell e assicurati di visualizzare l'ID progetto consumer.
3. Vai alla directory terraform-consumer cd terraform-consumer ed esegui il seguente comando terraform destroy e digita yes tutte le risorse che hai creato nel progetto db con Terraform verranno rimosse.

10. Complimenti

Congratulazioni, hai configurato correttamente un'istanza Cloud SQL con collegamento PSC e hai creato un endpoint Private Service Connect in un altro VPC. Sei riuscito a connetterti da una VM remota al database tramite l'endpoint PSC.

Scopri di più

Puoi scoprire di più su Private Service Connect e Cloud SQL.