PSA çalıştıran mevcut Cloud SQL örneğinde Private Service Connect'i etkinleştirme (Terraform)

1. Genel Bakış

Başka bir proje veya VPC ağından özel Cloud SQL örneğine bağlanmak için çeşitli seçenekler vardır. Özel bağlantılar üzerinden Google ve üçüncü taraf hizmetlerinin dahili IP adreslerine ulaşmak için özel hizmet erişimini (PSA) kullanabilirsiniz. Veritabanına erişimi genişletmek için artık Private Service Connect'i (PSC) de etkinleştirebilirsiniz.

Private Service Connect (PSC), hizmet üreticilerinin hizmetlerini hizmet ekleri aracılığıyla kullanıma sunmasına olanak tanır. Tüketiciler, bu ekleri kullanarak ortamlarında PSC uç noktaları ve/veya PSC arka uçları oluşturabilir. Bu PSC uç noktaları aracılığıyla, kullanıcı tarafından belirtilen özel bir IP üzerinden üretici hizmetlerine bağlanabilirler.

Bu laboratuvarda seçeneği yapılandırabilir ve test edebilirsiniz.

Not: Bu çözümün bazı sınırlamaları vardır. Bunları Private Service Connect sınırlaması bölümünde inceleyebilirsiniz.

Bu laboratuvarda, CloudSQL ile PSA ve PSC uç nokta erişiminin kullanımını gösteren basit bir mimari oluşturacaksınız.

Şekil 1.

Bu laboratuvar için iki projeye veya aynı projede ayrı VPC'lere ihtiyacınız vardır.

Not: Diğer bölgelerden kullanılabilmesi için PSC uç noktasında genel erişim etkinleştirilebilir.

Hedefler

Bu laboratuvarda, aşağıdaki görevi nasıl gerçekleştireceğinizi öğreneceksiniz:

• Hizmet ağı oluşturmayı etkinleştirme
• PSA'yı ayarlama
• PSA ile Cloud SQL örneği oluşturma
• PSC hizmet ekini etkinleştirin.
• Cloud SQL veritabanına bağlanmak için tüketici VPC'sinde bir PSC uç noktası oluşturun.
• Hem üretici hem de tüketici VPC'lerinde test sanal makinelerinden SQL veritabanına erişimi doğrulayın.

Not: Bu tasarım birden fazla tüketici tarafından kullanılabilir. Private Service Connect çoklu kiracılık hakkında bilgi edinin.

2. Kurulum ve Gereksinimler

Yönlendirmesiz ortam kurulumu

1. Google Cloud Console'da oturum açın ve yeni bir proje oluşturun veya mevcut bir projeyi yeniden kullanın. Gmail veya Google Workspace hesabınız yoksa hesap oluşturmanız gerekir.

• Proje adı, bu projenin katılımcıları için görünen addır. Google API'leri tarafından kullanılmayan bir karakter dizesidir. Bu bilgiyi istediğiniz zaman güncelleyebilirsiniz.
• Proje kimliği, tüm Google Cloud projelerinde benzersizdir ve sabittir (ayarlandıktan sonra değiştirilemez). Cloud Console, benzersiz bir dizeyi otomatik olarak oluşturur. Genellikle bu dizenin ne olduğuyla ilgilenmezsiniz. Çoğu codelab'de proje kimliğinize (genellikle PROJECT_ID olarak tanımlanır) başvurmanız gerekir. Oluşturulan kimliği beğenmezseniz başka bir rastgele kimlik oluşturabilirsiniz. Dilerseniz kendi adınızı deneyerek kullanılabilir olup olmadığını kontrol edebilirsiniz. Bu adım tamamlandıktan sonra değiştirilemez ve proje süresince geçerli kalır.
• Bazı API'lerin kullandığı üçüncü bir değer olan Proje Numarası da vardır. Bu üç değer hakkında daha fazla bilgiyi belgelerde bulabilirsiniz.

Dikkat: Proje kimliği genel olarak benzersizdir ve seçildikten sonra başka bir kullanıcı tarafından kullanılamaz. Bu kimliğin tek kullanıcısı sizsiniz. Proje silinse bile kimlik tekrar kullanılamaz.

Not: Gmail hesabı kullanıyorsanız varsayılan konumu Kuruluş yok olarak bırakabilirsiniz. Google Workspace hesabı kullanıyorsanız kuruluşunuz için uygun bir konum seçin.

2. Ardından, Cloud kaynaklarını/API'lerini kullanmak için Cloud Console'da faturalandırmayı etkinleştirmeniz gerekir. Bu codelab'i tamamlamak neredeyse hiç maliyetli değildir. Bu eğitimin ötesinde faturalandırılmayı önlemek için kaynakları kapatmak üzere oluşturduğunuz kaynakları veya projeyi silebilirsiniz. Yeni Google Cloud kullanıcıları 300 ABD doları değerinde ücretsiz deneme programından yararlanabilir.

Cloud Shell'i başlatma

Google Cloud, dizüstü bilgisayarınızdan uzaktan çalıştırılabilir ancak bu codelab'de Cloud'da çalışan bir komut satırı ortamı olan Google Cloud Shell'i kullanacaksınız.

Google Cloud Console'da sağ üstteki araç çubuğunda Cloud Shell simgesini tıklayın:

Ortamın temel hazırlığı ve bağlanması yalnızca birkaç dakikanızı alır. İşlem tamamlandığında aşağıdakine benzer bir ekranla karşılaşırsınız:

Bu sanal makine, ihtiyaç duyacağınız tüm geliştirme araçlarını içerir. 5 GB boyutunda kalıcı bir ana dizin sunar ve Google Cloud üzerinde çalışır. Bu sayede ağ performansı ve kimlik doğrulama önemli ölçüde güçlenir. Bu codelab'deki tüm çalışmalarınızı tarayıcıda yapabilirsiniz. Herhangi bir şey yüklemeniz gerekmez.

3. 1. görev: Veritabanı projesi için ortamı ayarlama (Terraform ile)

Etkinleştirdiğiniz bazı kaynakların maliyet oluşturacağını lütfen unutmayın. Maliyeti düşürmek için laboratuvar tamamlandıktan sonra kaynakların yok edildiğinden emin olun. Faturalandırmanızı kontrol etmenizi ve bu uygulamanın sizin için uygun olduğundan emin olmanızı öneririz.

Veritabanı projesinde hizmet ağı oluşturmayı etkinleştirecek, bir VPC oluşturacak, bir PSA aralığı oluşturacak, bir hizmet ağı eşlemesi oluşturacak ve güvenlik duvarı kuralları oluşturacağız. Cloud Console'u açın ve veritabanı için kullanacağınız projeyi seçin.

1. Konsolunuzun sağ üst kısmında bulunan Cloud Shell'i açın, Cloud Shell'de veritabanı projesi için veritabanı proje kimliğini gördüğünüzden emin olun ve erişime izin vermek için tüm istemleri onaylayın.
2. terraform-db-psc adlı bir klasör oluşturun ve bu klasöre gidin.

mkdir terraform-db-psc  && cd terraform-db-psc

3. main.tf, variable.tf, nat-vm.tf ve database.tf dosyası oluşturun.

touch main.tf variable.tf nat-vm.tf database.tf 

4. Cloud Shell Düzenleyici görünümüne geçin. Düzenleyici'yi seçin ve arayüzün yüklenebilmesi için gerekli istemlere izin verin.
5. Yüklendikten sonra File > Open Folder'a (Dosya > Klasörü Aç) gidin ve /home/your-user-name/terraform-db-psc'ye gidip Ok'u (Tamam) seçerek klasörü düzenleyicide açın.
6. variable.tf dosyasını seçin ve aşağıdakileri ekleyin. your-database-project-id-here metnini, tırnak işaretleri içinde gerçek veritabanı projesi kimliğinizle değiştirin. your-consumer-project-id-here metnini, tırnak işaretleri içinde gerçek proje kimliği ile değiştirin.

variable "project_id" {
  type = string
  default = "your-database-project-id-here"
}

variable "project_id_consumer" {
  type = set(string)
  default = ["your-consumer-project-id-here"]
}

variable "network_id" {
  type = string
  default = "database-net"
}

variable "region_id" {
  type = string
  default = "us-east1"
}

variable "db_password" {
  type = string
  default = "cloudsql24"
}

7. Ardından, main.tf dosyasını açın. Aşağıda açıklandığı gibi çeşitli işlemleri gerçekleştirmek için bazı Terraform kodları ekleyeceğiz.

API'leri etkinleştirme	resource "google_project_service" "default"
VPC oluşturma	resource "google_compute_network" "default"
Güvenlik duvarı kuralları ekleme	resource "google_compute_firewall" "allow_icmp"
PSA aralığı oluşturma	resource "google_compute_global_address" "psa_range"
Eşleme oluşturma	resource "google_service_networking_connection" "private_connection"

8. Aşağıdakileri kopyalayıp main .tf dosyasına yapıştırın.

resource "google_project_service" "default" {
 for_each = toset([
   "compute.googleapis.com",
   "servicenetworking.googleapis.com", 
   "sqladmin.googleapis.com",
   "cloudresourcemanager.googleapis.com"
 ])

 service            = each.value
 disable_on_destroy = false
}

resource "google_compute_network" "default" {
 project                = var.project_id
 name                    = var.network_id
 auto_create_subnetworks = true
 mtu                     = 1460
 routing_mode            = "GLOBAL"
}

resource "google_compute_global_address" "psa_range" {
  name                  = "psa-range-${google_compute_network.default.name}"
  project               = var.project_id
  purpose               = "VPC_PEERING"
  address_type          = "INTERNAL"
  prefix_length         = 20
  address               = "172.18.0.0"
  network               = google_compute_network.default.id

}

resource "google_service_networking_connection" "private_connection" {
  network = google_compute_network.default.self_link
  service = "servicenetworking.googleapis.com"

  reserved_peering_ranges = [
    google_compute_global_address.psa_range.name,
  ]
}

resource "google_compute_firewall" "allow_icmp" {
 name    = "allow-icmp-${google_compute_network.default.name}"
 network = google_compute_network.default.id
 project = var.project_id

 allow {
   protocol = "icmp"
 }

 source_ranges = ["0.0.0.0/0"]
 target_tags   = ["allow-icmp"]
}

resource "google_compute_firewall" "allow_ssh" {
 name    = "allow-ssh-${google_compute_network.default.name}"
 network = google_compute_network.default.id
 project = var.project_id

 allow {
   protocol = "tcp"
   ports    = ["22"]
 }

 source_ranges = ["0.0.0.0/0"]
 target_tags   = ["allow-ssh"]
}

resource "google_compute_firewall" "allow_sql" {
 name    = "allow-sql-${google_compute_network.default.name}"
 network = google_compute_network.default.id
 project = var.project_id

 allow {
   protocol = "tcp"
   ports    = ["3306"]
 }

 source_ranges = ["0.0.0.0/0"]
}

resource "google_compute_firewall" "allow_internal" {
 name    = "allow-internal-${google_compute_network.default.name}"
 network = google_compute_network.default.id
 project = var.project_id

 allow {
   protocol = "icmp"
 }

 allow {
   protocol = "tcp"
   ports    = ["0-65535"]
 }
 allow {
   protocol = "udp"
   ports    = ["0-65535"]
 }

 source_ranges = ["10.128.0.0/9", "172.18.0.0/20"] # Include PSA range
}

9. Cloud Shell terminaline geri dönün, terraform-db-psc dizininde olduğunuzdan emin olun cd terraform-db-psc ve aşağıdaki komutları çalıştırın.

terraform init

Çalışma dizinini başlatır. Bu adımda, söz konusu yapılandırma için gerekli sağlayıcılar indirilir.

terraform plan

Terraform'un altyapınızı dağıtmak için hangi işlemleri yapacağını gösteren bir yürütme planı oluşturur.

10. Şimdi kaynakları oluşturmak için terraform apply komutunu çalıştırın ve çalıştırmak için yes yazın.

Kurulumunuzu doğrulayın:

Ortamınızda, hizmet ağı etkin VPC ağı eşli PSA IP aralığı ayrılıp ayrılmadığını kontrol edin.

database-net adlı otomatik modda VPC oluşturuldu

Güvenlik duvarı kuralları oluşturuldu

4. 2. görev: PSA ile Cloud SQL örneği oluşturma (Terraform)

Bağlantıya izin vermek için PSA seçeneğiyle Cloud SQL örneği oluşturmak üzere Terraform'u kullanalım. Bu yapılandırmayı veritabanı projesinde tamamlayın.

1. Cloud Shell Düzenleyici görünümüne geçin. terraform-db-psc klasöründe olduğunuzdan emin olun. database.tf dosyasını seçin ve aşağıdakileri ekleyin.

resource "google_sql_database_instance" "default" {
  name             = "psc-psa-sql-db"
  region           = var.region_id
  database_version = "MYSQL_8_0"  
  settings {
    tier              = "db-f1-micro"
    availability_type = "REGIONAL"
    backup_configuration {
      enabled            = true
      binary_log_enabled = true
    }
    ip_configuration {      
      ipv4_enabled    = "false"
      private_network = google_compute_network.default.id
      
    }
  }
  deletion_protection = false 
}

resource "google_sql_user" "users" {
  name     = "testsql"
  instance = google_sql_database_instance.default.name
  password = var.db_password 
}

2. Cloud Shell terminaline geri dönün ve terraform-db-psc dizininde olduğunuzdan emin olun. Şimdi kaynakları oluşturmak için terraform apply komutunu çalıştırın ve çalıştırmak için yes yazın. PSA ile Cloud SQL örneği oluşturma işlemi 15 dakikadan uzun sürebilir.

Veritabanını doğrulama

3. İşlem tamamlandıktan sonra konsolda SQL'e gidin ve yeni oluşturulan psc-psa-sql-db veritabanı örneğini seçin.
4. Sol tarafta SQL seçenekleri kaydırma panelini genişletin ve Bağlantılar'ı seçin.
5. Özet sekmesinde bağlantıyla ilgili bilgileri görebilirsiniz.
6. Dahili IP adresini kopyalayın ve sisteminizde bir yere kaydedin. Gördüğünüz gibi, ayırdığımız aralıktan bir adres atanmış.
7. 3. görevin 5. adımını tamamlamak için bu IP'ye ihtiyacınız olacaktır.

8. Sol tarafta SQL seçenekleri açılır menüsünü genişletin ve Kullanıcılar'ı seçin.
9. testsql adlı kullanıcının şifresi cloudsql24 olmalıdır (Bu şifre, daha sonra veritabanına erişmek için kullanılacaktır).

Kurulumunuzu doğrulayın:

Özel IP'ye sahip 1 SQL veritabanı örneği

testsql adlı bir kullanıcı ve cloudsql24 şifresi

5. 3. görev: Test sanal makinesi oluşturma ve veritabanı projesinden SQL örneğine bağlanma (Terraform)

Test VM'si ve NAT ağ geçidi oluşturmak için Terraform'u kullanalım. Bu yapılandırmayı veritabanı projesinde tamamlayın.

1. Cloud Shell Düzenleyici görünümüne geçin. terraform-db-psc klasöründe olduğunuzdan emin olun. nat-vm.tf dosyasını seçin ve aşağıdakileri ekleyin.

resource "google_compute_router" "default" {
  name    = "outbound-nat"
  region  = var.region_id
  network = google_compute_network.default.id

 bgp {
  asn = 64514
  }
}

resource "google_compute_router_nat" "default" {
  name = "outbound-nat-gw"
  router = google_compute_router.default.name
  region = google_compute_router.default.region
  nat_ip_allocate_option = "AUTO_ONLY"
  source_subnetwork_ip_ranges_to_nat = "ALL_SUBNETWORKS_ALL_IP_RANGES"

  log_config {
    enable = true
    filter = "ERRORS_ONLY"
  }
}


resource "google_compute_instance" "sql_net_vm" {
  name         = "db-vm-test"
  machine_type = "e2-medium"
  zone         = "${var.region_id}-b"
  project      = var.project_id

  boot_disk {
    initialize_params {
      image = "debian-cloud/debian-11"
    }
  }

  network_interface {
    network = google_compute_network.default.self_link
  }

  # No external IP address
  network_performance_config {
    total_egress_bandwidth_tier = "DEFAULT"
  }

  tags = ["allow-icmp", "allow-ssh", "allow-internal", "allow-health-check"]

  # Install MariaDB at startup
  metadata_startup_script = <<EOF
#!/bin/bash
apt-get update
apt-get install -y mariadb-server
systemctl enable mariadb
EOF
}

2. Cloud Shell terminaline geri dönün ve terraform-db-psc dizininde olduğunuzdan emin olun. Şimdi kaynakları oluşturmak için terraform plan, then terraform apply komutunu çalıştırın ve çalıştırmak için yes yazın. Bu işlem, MariaDB'nin yüklü olduğu bir NAT ağ geçidi ve sanal makine oluşturur.

Veritabanını doğrulama

Bu işlemi tüketici projesinde tamamlayın

3. Sanal Makine Örneği'ne gidin. db-vm-test'i seçin.
4. Sanal makineye bağlanmak için SSH seçeneğini belirleyin.
5. Aşağıdaki komutla daha önce kopyaladığınız yerel IP aracılığıyla DB'ye bağlanın:

mysql --host=172.18.0.2 --user=testsql --password=cloudsql24

Not: Bağlanması için IP adresini gerçek IP'nizle değiştirin.

6. Bağlantı kurulduktan sonra aşağıdaki localvpcsqldb ile bir veritabanı oluşturun.

CREATE DATABASE localvpcsqldb;

7. İşlem tamamlandığında bağlantıdan çıkmak için exit yazın. Sanal makineyi kapatmak için tekrar exit yazın.

Kurulumunuzu doğrulayın:

1 NAT ağ geçidi

db-vm-test adlı 1 sanal makine

6. 4. görev: Cloud SQL örneğinde PSC'yi etkinleştirme

Bağlantıya izin vermek için PSC seçeneğini etkinleştirmek üzere gcloud komutlarını kullanalım. Bu yapılandırmayı veritabanı projesinde tamamlayın.

1. Cloud Shell görünümüne geçin.
2. Cloud Shell'de aşağıdaki komutu çalıştırın.

• Ensure YOUR_DB_PROJECT_HERE ifadesini veritabanı projesi kimliğiyle değiştirin.
• Ensure YOUR_CONSUMER_PROJECT_HERE kısmını tüketici projesi kimliğiyle değiştirin.

project_id=YOUR_DB_PROJECT_HERE
allowed_project=YOUR_CONSUMER_PROJECT_HERE

gcloud beta sql instances patch psc-psa-sql-db \
--project=$project_id \
--enable-private-service-connect \
--allowed-psc-projects=$allowed_project

3. Bu işlem, mevcut veritabanını PSC ekiyle günceller. Bu işlem biraz zaman alır (10 dakika veya daha uzun).

Zaman aşımı bekleme hatası alırsanız ilerlemeyi görmeye devam etmenizi sağlayacak komut da verilir. "`gcloud beta sql operations wait –project komutunu çalıştırarak işlemin tamamlanmasını beklemeye devam edebilirsiniz." gibi bir mesaj gösterilir.

Lütfen PSA ve PSC'nin etkin olduğu yeni bir veritabanını başlangıçtan itibaren dağıtabileceğinizi unutmayın.

Veritabanını doğrulama

4. İşlem tamamlandıktan sonra konsolda SQL'e gidin ve psc-psa-sql-db veritabanı örneğini seçin.
5. Sol tarafta SQL seçenekleri kaydırma panelini genişletin ve Bağlantılar'ı seçin.
6. Özet sekmesinde bağlantıyla ilgili bilgileri görebilirsiniz.
7. Hizmet eki adresini kopyalayın ve sisteminizde bir yere kaydedin.
8. Bir sonraki görev olan 5. adımın 8. bölümünü tamamlamak için bu bilgiye ihtiyacınız olacaktır.

Kurulumunuzu doğrulayın:

Hizmet eki içeren 1 SQL veritabanı örneği

7. 5. görev: Tüketici projesi için ortamı ayarlama (Terraform)

Tüketici projesinde,güvenlik duvarı kuralları ve alt ağ içeren özel bir VPC oluşturacağız. Cloud Console'u açın ve kullanacağınız projeyi seçin.

1. Konsolunuzun üst kısmında, sağ tarafta Google Cloud simgesinin yanındaki açılır listeyi tıklayın ve tümü sekmesini seçin.

2. Devam etmek için listelenen projelerden tüketici projesi kimliğinizi seçin.
3. Konsolunuzun sağ üst kısmında bulunan Cloud Shell'i açın, Cloud Shell'de tüketici proje kimliğini gördüğünüzden emin olun ve erişime izin vermek için tüm istemleri onaylayın.
4. terraform-consumer-psc adlı bir klasör oluşturun ve bu klasöre gidin.

mkdir terraform-consumer-psc  && cd terraform-consumer-psc

5. main.tf, variable.tf ve psc.tf dosyası oluşturun.

touch main.tf variable.tf psc.tf 

6. Tüketici projesi kimliği için Cloud Shell düzenleyici görünümüne geçin. Düzenleyici'yi seçin ve arayüzün yüklenebilmesi için gerekli istemlere izin verin.
7. Yüklendikten sonra File > Open Folder'a (Dosya > Klasör Aç) gidin ve /home/your-user-name/terraform-consumer-psc'ye gidip Ok'u (Tamam) seçerek klasörü düzenleyicide açın.
8. variable.tf dosyasını seçin ve aşağıdakileri ekleyin. your-consumer-project-id-here metnini tırnak işaretleri içinde gerçek tüketici proje kimliğinizle değiştirin. your-psc-attachment-id-here metnini tırnak işaretleri içinde psc eki adresinizle değiştirin. Bu, görev 4 bölüm 5-7'de kopyaladığınız kimliktir.

variable "project_id" {
  type = string
  default = "your-consumer-project-id-here"
}

variable "psc_attachment_id" {
  type = string
  default = "your-psc-attachment-id-here"
}

variable "network_id" {
  type = string
  default = "psc-endpoint-vpc"
}

variable "region_id" {
  type = string
  default = "us-east1"
}

9. Ardından, main.tf dosyasını açın. Aşağıda açıklandığı gibi çeşitli işlemleri gerçekleştirmek için bazı Terraform kodları ekleyeceğiz.

API'leri etkinleştirme	resource "google_project_service"
VPC oluşturma	resource "google_compute_network"
NAT ağ geçidi oluşturma	resource "google_compute_router" resource "google_compute_router_nat"
Güvenlik duvarı kuralları ekleme	resource "google_compute_firewall"

10. Aşağıdakileri kopyalayıp main .tf dosyasına yapıştırın.

resource "google_project_service" "default" {
  for_each = toset([
    "compute.googleapis.com",
    "cloudresourcemanager.googleapis.com"
  ])

  service            = each.value
  disable_on_destroy = false
}

resource "google_compute_network" "default" {
  project                 = var.project_id
  name                    = var.network_id
  auto_create_subnetworks = false
  mtu                     = 1460
  routing_mode            = "GLOBAL"
}

resource "google_compute_subnetwork" "vm_subnet_pc" {
  name          = "vm-net"
  ip_cidr_range = "192.168.80.0/24"
  region        = var.region_id
  network       = google_compute_network.default.name
  project       = var.project_id
}

resource "google_compute_subnetwork" "psc_subnet_ip" {
  name          = "psc-subnet"
  ip_cidr_range = "192.168.100.0/24"
  region        = var.region_id
  network       = google_compute_network.default.name
  project       = var.project_id
}

resource "google_compute_router" "default" {
  name    = "outbound-nat"
  region  = var.region_id
  network = google_compute_network.default.id

 bgp {
  asn = 64514
  }
}

resource "google_compute_router_nat" "default" {
  name = "outbound-nat-gw"
  router = google_compute_router.default.name
  region = google_compute_router.default.region
  nat_ip_allocate_option = "AUTO_ONLY"
  source_subnetwork_ip_ranges_to_nat = "ALL_SUBNETWORKS_ALL_IP_RANGES"

  log_config {
    enable = true
    filter = "ERRORS_ONLY"
  }
}

resource "google_compute_firewall" "allow_icmp" {
  name    = "allow-icmp-${google_compute_network.default.name}"
  network = google_compute_network.default.id
  project = var.project_id

  allow {
    protocol = "icmp"
  }

  source_ranges = ["0.0.0.0/0"]
  
}

resource "google_compute_firewall" "allow_ssh" {
  name    = "allow-ssh-${google_compute_network.default.name}"
  network = google_compute_network.default.id
  project = var.project_id

  allow {
    protocol = "tcp"
    ports    = ["22"]
  }

  source_ranges = ["0.0.0.0/0"]
  target_tags   = ["allow-ssh"]
}


resource "google_compute_firewall" "allow_internal" {
  name    = "allow-internal-${google_compute_network.default.name}"
  network = google_compute_network.default.id
  project = var.project_id

  allow {
    protocol = "icmp"
    }


  allow {
    protocol = "tcp"
    ports    = ["0-65535"]
  }
  allow {
    protocol = "udp"
    ports    = ["0-65535"]
  }

  source_ranges = ["192.168.0.0/16"]
 }

11. Cloud Shell terminaline geri dönün, tüketici projesindeki terraform-consumer-psc dizininde olduğunuzdan emin olun cd terraform-consumer-psc ve aşağıdaki komutları çalıştırın.

terraform init

Çalışma dizinini başlatır. Bu adımda, söz konusu yapılandırma için gerekli sağlayıcılar indirilir.

terraform plan

Terraform'un altyapınızı dağıtmak için hangi işlemleri yapacağını gösteren bir yürütme planı oluşturur.

12. Şimdi kaynakları oluşturmak için terraform apply komutunu çalıştırın ve çalıştırmak için yes yazın.

Kurulumunuzu doğrulayın:

Aşağıdaki durumlar için ortamınızı kontrol edin:

psc-endpoint-vpc adlı 1 özel VPC

Güvenlik duvarı kuralları NAT ağ geçidi

8. 6. görev: Tüketici projesinde SQL DB eki için PSC uç noktası oluşturma ve sanal makineyi test etme (Terraform)

Bu yapılandırmayı tüketici projesinde tamamlayın.

1. Cloud Shell düzenleyiciye geri dönün, terraform-consumer-psc dizinini açın ve psc.tf dosyasını seçin. Aşağıdaki Terraform kodunu dosyaya ekleyin. Bu işlemle statik dahili IP, PSC uç noktası ve Maria DB'nin yüklü olduğu bir test sanal makinesi oluşturulur.

resource "google_compute_address" "default" {
  name = "psc-ip-1"
  region = var.region_id
  address_type = "INTERNAL"
  subnetwork = google_compute_subnetwork.psc_subnet_ip.name
  address = "192.168.100.100" 
}

resource "google_compute_forwarding_rule" "default" {
  name = "psc-sql-endpoint"
  region = var.region_id
  network = google_compute_network.default.name
  ip_address = google_compute_address.default.self_link
  load_balancing_scheme = ""
  target = var.psc_attachment_id
}


resource "google_compute_instance" "sql_test_vm" {
  name         = "remote-sql-test-vm"
  machine_type = "e2-medium"
  zone         = "${var.region_id}-b"
  project      = var.project_id

  boot_disk {
    initialize_params {
      image = "debian-cloud/debian-11"
    }
  }

  network_interface {
    subnetwork = google_compute_subnetwork.vm_subnet_pc.name
  }

  # No external IP address
  network_performance_config {
    total_egress_bandwidth_tier = "DEFAULT"
  }

  tags = ["allow-icmp", "allow-ssh", "allow-internal", "allow-health-check"]

  # Install MariaDB at startup
  metadata_startup_script = <<EOF
#!/bin/bash
apt-get update
apt-get install -y mariadb-server
systemctl enable mariadb
EOF
}

2. Cloud Shell terminaline geri dönün, tüketici projesindeki terraform-consumer-psc dizininde olduğunuzdan emin olun cd terraform-consumer-psc ve aşağıdaki komutları çalıştırın.

terraform plan

Terraform'un altyapınızı dağıtmak için hangi işlemleri yapacağını gösteren bir yürütme planı oluşturur.

3. Şimdi kaynakları oluşturmak için terraform apply komutunu çalıştırın ve çalıştırmak için yes yazın.

9. 7. görev: PSC IP adresi üzerinden sanal makineden uç nokta bağlantısını doğrulama

Bu işlemi tüketici projesinde tamamlayın

8. Sanal Makine Örneği'ne gidin. remote-sql-test-vm'yi seçin.
9. Sanal makineye bağlanmak için SSH seçeneğini belirleyin.
10. Aşağıdaki bilgilerle uç nokta üzerinden DB'ye bağlanın:

mysql --host=192.168.100.100 --user=testsql --password=cloudsql24

11. Bağlantı kurulduktan sonra aşağıdaki psc-sql-db ile bir veritabanı oluşturun.

CREATE DATABASE remotepscpsasqldb;

12. İşlem tamamlandığında bağlantıdan çıkmak için exit yazın. Sanal makineyi kapatmak için tekrar exit yazın.

10. 8. görev: Veritabanı girişini doğrulama

Bu doğrulamayı veritabanı projesinde tamamlayın.

1. Konsolunuzun üst kısmında, sağ tarafta Google Cloud simgesinin yanındaki açılır listeyi tıklayın ve tümü sekmesini seçin.

2. Devam etmek için listelenen projelerden veritabanı proje kimliğinizi seçin.
3. SQL'e gidin, psc-psa-sql-db veritabanını seçin, SQL seçeneklerini genişletin ve Veritabanları'nı seçin. Tüketici projesi sanal makinesinden remotepscpsasqldb adlı yeni oluşturduğunuz veritabanını ve veritabanı projesi sanal makinesinden localvpcsqldb adlı veritabanını görmeniz gerekir.**.**

Not: DNS adı kullanarak da bağlanabilirsiniz. DNS'yi ayarlama hakkında daha fazla bilgiyi DNS tarafından yönetilen bir bölge ve DNS kaydı yapılandırma başlıklı makalede bulabilirsiniz.

11. Temizleme

Gereksiz ücretleri önlemek için temizlik yaptığınızdan emin olun.

Bu işlemi tüketici projesinde tamamlayın

1. Tüketici projesi kimliğini seçin
2. Cloud Shell'e gidin ve tüketici proje kimliğini gördüğünüzden emin olun.
3. terraform-consumer-psc dizinine gidin cd terraform-consumer-psc ve aşağıdaki komutu çalıştırın terraform destroy ve yes yazın. Tüketici projenizde Terraform ile oluşturduğunuz tüm kaynaklar kaldırılacak.

Bu işlemi Veritabanı projesinde tamamlama

1. Veritabanı proje kimliğini seçin
2. Cloud Shell'e gidin ve veritabanı proje kimliğini gördüğünüzden emin olun.
3. terraform-db-psc dizinine gidin cd terraform-db-psc ve aşağıdaki komutu çalıştırın terraform destroy. yes yazın. Terraform ile veritabanı projenizde oluşturduğunuz kaynakların çoğu kaldırılır. Hizmet ağı silinemeyebilir ve hata verebilir.
4. Ardından, terraform-db-psc klasöründeki aşağıdaki dosyaları silin.

rm -r terraform.tfstate terraform.tfstate.backup

5. Ardından konsolda VPC ağları'na gidin.
6. database-net VPC'yi seçin, PRIVATE SERVICES ACCESS'i seçin, Allocated IP Ranges for Services (Hizmetler İçin Ayrılan IP Aralıkları) bölümünde psa-range-database-net'i seçin ve Release (Yayınla) seçeneğini belirleyin.

7. Ardından VPC NETWORK PEERING'i,servicenetworking-googleapis-com'u ve Sil seçeneğini belirleyin.

8. Ardından VPC ağını sil 'i seçin. 

12. Tebrikler

Tebrikler, PSA ve PSC ekiyle bir Cloud SQL örneğini başarıyla yapılandırdınız ve başka bir VPC'de Private Service Connect uç noktası oluşturdunuz.

Daha fazla bilgi

Private Service Connect ve Cloud SQL hakkında daha fazla bilgi edinebilirsiniz.

Diğer ilgili codelab: https://codelabs.developers.google.com/codelabs/cloudsql-psc-terraform