Private Service Connect एंडपॉइंट के ज़रिए, GCE पर Antigravity CLI को रन करना

1. खास जानकारी

Antigravity CLI का इस्तेमाल, लोकल और वर्चुअल, दोनों तरह के एनवायरमेंट में किया जा सकता है. Antigravity, Gemini की सुविधा सीधे आपके टर्मिनल में उपलब्ध कराता है. नेटवर्किंग के हिसाब से, Antigravity CLI का इस्तेमाल करने पर, यह Gemini API को कॉल करेगा. इसके लिए, यह एपीआई के आईपी पते का इस्तेमाल करेगा. यह आईपी पता सार्वजनिक तौर पर उपलब्ध होता है.

अब अगर आपको Google Compute Engine मशीन पर Antigravity CLI का इस्तेमाल करना है, लेकिन आपको एपीआई से निजी तौर पर कनेक्ट करना है, तो क्या होगा? इस कोडलैब में, आपको Google APIs के लिए Private Service Connect एंडपॉइंट को कॉन्फ़िगर करने का तरीका बताया जाएगा. इससे, ट्रैफ़िक को आपके बताए गए इंटरनल आईपी पते पर भेजा जा सकेगा.

कॉन्फ़िगरेशन, Terraform, gcloud, और कंसोल का कॉम्बिनेशन होगा.

इस लैब में, आपको यह टास्क पूरा करने का तरीका बताया जाएगा:

• वीएम इंस्टेंस और Cloud NAT सेट अप करना
• Antigravity सीएलआई इंस्टॉल करना और पुष्टि करना
• Googleapis से कनेक्ट करने के लिए, Private Service Connect एंडपॉइंट को कॉन्फ़िगर करना
• *.googleapis से कनेक्टिविटी के पाथ की पुष्टि करना
• डीएनएस की मैन्युअल एंट्री कॉन्फ़िगर करना

इस लैब में, आपको यह पैटर्न बनाना है.

इमेज 1.

2. Google Cloud की सेवाओं का सेटअप

अपने हिसाब से एनवायरमेंट सेटअप करना

1. Google Cloud Console में साइन इन करें और नया प्रोजेक्ट बनाएं या किसी मौजूदा प्रोजेक्ट का फिर से इस्तेमाल करें. अगर आपके पास पहले से कोई Gmail या Google Workspace खाता नहीं है, तो आपको एक खाता बनाना होगा.

• प्रोजेक्ट का नाम, इस प्रोजेक्ट में हिस्सा लेने वाले लोगों के लिए डिसप्ले नेम होता है. यह एक वर्ण स्ट्रिंग है, जिसका इस्तेमाल Google API नहीं करते. इसे कभी भी अपडेट किया जा सकता है.
• प्रोजेक्ट आईडी, सभी Google Cloud प्रोजेक्ट के लिए यूनीक होता है. साथ ही, इसे बदला नहीं जा सकता. Cloud Console, एक यूनीक स्ट्रिंग अपने-आप जनरेट करता है. आम तौर पर, आपको इससे कोई फ़र्क़ नहीं पड़ता कि यह क्या है. ज़्यादातर कोडलैब में, आपको अपने प्रोजेक्ट आईडी (आम तौर पर PROJECT_ID के तौर पर पहचाना जाता है) का रेफ़रंस देना होगा. अगर आपको जनरेट किया गया आईडी पसंद नहीं है, तो कोई दूसरा रैंडम आईडी जनरेट किया जा सकता है. इसके अलावा, आपके पास अपना नाम आज़माने का विकल्प भी है. इससे आपको पता चलेगा कि वह नाम उपलब्ध है या नहीं. इस चरण के बाद, इसे बदला नहीं जा सकता. यह प्रोजेक्ट की अवधि तक बना रहता है.
• आपकी जानकारी के लिए बता दें कि एक तीसरी वैल्यू भी होती है, जिसे प्रोजेक्ट नंबर कहते हैं. इसका इस्तेमाल कुछ एपीआई करते हैं. इन तीनों वैल्यू के बारे में ज़्यादा जानने के लिए, दस्तावेज़ देखें.

चेतावनी: प्रोजेक्ट आईडी, दुनिया भर में यूनीक होता है. इसे चुनने के बाद, कोई और इसका इस्तेमाल नहीं कर सकता. उस आईडी का इस्तेमाल सिर्फ़ आपके पास हो. प्रोजेक्ट मिटाने के बाद भी, आईडी का दोबारा इस्तेमाल नहीं किया जा सकता

ध्यान दें: अगर Gmail खाते का इस्तेमाल किया जाता है, तो डिफ़ॉल्ट तौर पर सेट की गई जगह को कोई संगठन नहीं पर सेट किया जा सकता है. अगर Google Workspace खाते का इस्तेमाल किया जा रहा है, तो अपने संगठन के हिसाब से कोई जगह चुनें.

2. इसके बाद, आपको Cloud Console में बिलिंग चालू करनी होगी, ताकि Cloud संसाधनों/एपीआई का इस्तेमाल किया जा सके. इस कोडलैब को पूरा करने में ज़्यादा समय नहीं लगेगा. इस ट्यूटोरियल के बाद बिलिंग से बचने के लिए, संसाधनों को बंद किया जा सकता है. इसके लिए, बनाए गए संसाधनों को मिटाएं या प्रोजेक्ट को मिटाएं. Google Cloud के नए उपयोगकर्ताओं को, 300 डॉलर का क्रेडिट मुफ़्त में आज़माने का प्रोग्राम मिलता है.

Cloud Shell शुरू करें

Google Cloud को अपने लैपटॉप से रिमोटली ऐक्सेस किया जा सकता है. हालांकि, इस कोडलैब में Google Cloud Shell का इस्तेमाल किया जाएगा. यह क्लाउड में चलने वाला कमांड लाइन एनवायरमेंट है.

Google Cloud Console में, सबसे ऊपर दाएं कोने में मौजूद टूलबार पर, Cloud Shell आइकॉन पर क्लिक करें:

इसे चालू करने और एनवायरमेंट से कनेक्ट करने में सिर्फ़ कुछ सेकंड लगेंगे. यह प्रोसेस पूरी होने के बाद, आपको कुछ ऐसा दिखेगा:

इस वर्चुअल मशीन में, डेवलपमेंट के लिए ज़रूरी सभी टूल पहले से मौजूद होते हैं. यह 5 जीबी की होम डायरेक्ट्री उपलब्ध कराता है. साथ ही, Google Cloud पर काम करता है. इससे नेटवर्क की परफ़ॉर्मेंस और पुष्टि करने की प्रोसेस बेहतर होती है. इस कोडलैब में मौजूद सभी टास्क, ब्राउज़र में किए जा सकते हैं. आपको कुछ भी इंस्टॉल करने की ज़रूरत नहीं है.

3. Terraform की मदद से एनवायरमेंट सेट अप करना

हम फ़ायरवॉल के नियमों और सबनेट के साथ एक कस्टम वीपीसी बनाएंगे. क्लाउड कंसोल खोलें और वह प्रोजेक्ट चुनें जिसका आपको इस्तेमाल करना है.

1. अपनी कंसोल के सबसे ऊपर दाईं ओर मौजूद Cloud Shell खोलें. पक्का करें कि आपको Cloud Shell में सही प्रोजेक्ट आईडी दिख रहा हो. साथ ही, ऐक्सेस की अनुमति देने के लिए दिए गए किसी भी प्रॉम्प्ट की पुष्टि करें.
2. terraform-build नाम का फ़ोल्डर बनाओ और उसमें जाओ

mkdir terraform-build && cd terraform-build 

3. main.tf और variable.tf फ़ाइल बनाएं.

touch main.tf variable.tf 

4. Cloud Shell एडिटर व्यू पर स्विच करें. एडिटर को चुनें. साथ ही, पक्का करें कि आपने सभी ज़रूरी प्रॉम्प्ट को अनुमति दी हो, ताकि इंटरफ़ेस लोड हो सके.
5. लोड होने के बाद, फ़ाइल > फ़ोल्डर खोलें पर जाएं. इसके बाद, /home/your-user-name/terraform-build पर जाएं और ठीक है को चुनें, ताकि फ़ोल्डर को एडिटर में खोला जा सके.
6. variable.tf फ़ाइल चुनें और इसमें यह कोड जोड़ें. your-project-id-here टेक्स्ट की जगह, कोटेशन मार्क में अपना प्रोजेक्ट आईडी डालें

variable "project_id" {
  type = string
  default = "your-project-id-here"
}

variable "network_id" {
  type = string
  default = "antigravity-vpc-net"
}

7. इसके बाद, main.tf फ़ाइल खोलें. हम यहां कुछ टेराफ़ॉर्म कोड जोड़ने जा रहे हैं, ताकि नीचे बताई गई कार्रवाइयां की जा सकें.

एपीआई चालू करना	resource "google_project_service" "default"
python-net नाम का वीपीसी बनाएं	resource "google_compute_network" "default"
सबनेट जोड़ना	resource "google_compute_subnetwork" "default"
फ़ायरवॉल के दो नियम जोड़ना	resource "google_compute_firewall" "allow_icmp"resource "google_compute_firewall" "allow_ssh"

8. यहां दिए गए कोड को कॉपी करके, main .tf फ़ाइल में चिपकाएं.

resource "google_project_service" "default" {
  for_each = toset([
    "dns.googleapis.com",
    "aiplatform.googleapis.com",
    "servicedirectory.googleapis.com"
  ])

  service            = each.value
  disable_on_destroy = false
}

resource "google_compute_network" "default" {
  project                 = var.project_id
  name                    = var.network_id
  auto_create_subnetworks = false
  mtu                     = 1460
  routing_mode            = "GLOBAL"
}

resource "google_compute_subnetwork" "default" {
  name          = "vm1-subnet"
  ip_cidr_range = "192.168.100.0/24"
  region        = "us-east1"
  stack_type    = "IPV4_ONLY"
  network       = google_compute_network.default.id
}

resource "google_compute_firewall" "allow_icmp" {
  name    = "allow-icmp-${google_compute_network.default.name}"
  network = google_compute_network.default.id
  project = var.project_id

  allow {
    protocol = "icmp"
  }

  source_ranges = ["0.0.0.0/0"]
  target_tags   = ["allow-icmp"]
}

resource "google_compute_firewall" "allow_ssh" {
  name    = "allow-ssh-${google_compute_network.default.name}"
  network = google_compute_network.default.id
  project = var.project_id

  allow {
    protocol = "tcp"
    ports    = ["22"]
  }

  source_ranges = ["0.0.0.0/0"]
  target_tags   = ["allow-ssh"]
}

9. Cloud Shell टर्मिनल पर वापस जाएं. पक्का करें कि आप terraform-build डायरेक्ट्री cd terraform-build में हों. इसके बाद, ये कमांड चलाएं

terraform init

इससे वर्किंग डायरेक्ट्री शुरू होती है. इस चरण में, दिए गए कॉन्फ़िगरेशन के लिए ज़रूरी प्रोवाइडर डाउनलोड किए जाते हैं.

terraform plan

यह एक एक्ज़ीक्यूशन प्लान जनरेट करता है. इससे पता चलता है कि आपके इन्फ़्रास्ट्रक्चर को डिप्लॉय करने के लिए, Terraform कौनसी कार्रवाइयां करेगा.

10. अब संसाधन बनाने के लिए, terraform apply कमांड चलाएं और चलाने के लिए yes टाइप करें.

अपने सेटअप की पुष्टि करें: अपने एनवायरमेंट में इन चीज़ों की जांच करें

• antigravity-vpc-net नाम का वीपीसी
• सबनेट
• firewall-rules

4. टास्क 2. Terraform की मदद से NAT गेटवे और वीएम बनाना

हमें इंटरनेट के लिए आउटबाउंड बाहरी ऐक्सेस देना होगा. इसलिए, Cloud NAT गेटवे बनाते हैं और उसे अटैच करते हैं.

1. Cloud Shell खोलें. इसके बाद, terraform-build फ़ोल्डर पर जाएं और यहां दी गई तीन फ़ाइलें बनाएं. हम इनमें बाद में बदलाव करेंगे.

touch nat-vm.tf psc.tf dns.tf

2. Cloud Shell एडिटर व्यू पर स्विच करें. इसके बाद, nat-vm.tf फ़ाइल चुनें और यह Terraform कोड जोड़ें. इससे एक NAT गेटवे और दो वीएम बन जाएंगे.

Terraform nat-vm.tf

resource "google_compute_router" "default" {
  name    = "outbound-nat"
  region  = "us-east1"
  network = google_compute_network.default.id

 bgp {
  asn = 64514
  }
}

resource "google_compute_router_nat" "default" {
  name                               = "outbound-gw"
  router                             = google_compute_router.default.name
  region                             = google_compute_router.default.region
  nat_ip_allocate_option             = "AUTO_ONLY"
  source_subnetwork_ip_ranges_to_nat = "ALL_SUBNETWORKS_ALL_IP_RANGES"

  log_config {
    enable = true
    filter = "ERRORS_ONLY"
  }
}

resource "google_compute_instance" "vm1" {
  name         = "cli-vm"
  zone         = "us-east1-b"
  machine_type = "n2-standard-2"

  boot_disk {
    initialize_params {
      image = "debian-cloud/debian-12"
    }
  }

  network_interface {
    subnetwork = google_compute_subnetwork.default.id  
    stack_type = "IPV4_ONLY"
  }

  tags = ["allow-ssh", "allow-icmp"]

  metadata_startup_script = <<-EOF
    sudo apt-get update    
  EOF
}

resource "google_compute_instance" "vm2" {
  name         = "monitor-vm"
  zone         = "us-east1-b"
  machine_type = "n2-standard-2"

  boot_disk {
    initialize_params {
      image = "debian-cloud/debian-12"
    }
  }

  network_interface {
    subnetwork = google_compute_subnetwork.default.id   
    stack_type = "IPV4_ONLY"
  }

  tags = ["allow-ssh", "allow-icmp"]

  metadata_startup_script = <<-EOF
    sudo apt-get update
    sudo apt-get install python3 python3-dev python3-venv -y
    sudo apt-get install tcpdump dnsutils -y
  EOF
}

3. Cloud Shell टर्मिनल पर जाएं. पक्का करें कि आप terraform-build फ़ोल्डर में हों. इसके बाद, terraform plan चलाएं. इससे आपको पता चलेगा कि चार आइटम जोड़े जाएंगे. इसके बाद, terraform apply चलाएं और NAT गेटवे और दो वीएम बनाने के लिए, yes टाइप करें.

अपने सेटअप की पुष्टि करें: अपने एनवायरमेंट में इन चीज़ों की जांच करें

1 NAT गेटवे

एक क्लाउड राऊटर

cli-vm नाम की वीएम

monitor-vm नाम की वीएम

5. टास्क 3. सीएलआई वीएम कॉन्फ़िगर करना और उनकी जांच करना

1. वीएम इंस्टेंस पर जाएं. cli-vm से शुरू होने वाली वीएम को चुनें. SSH को चुनें.
2. एसएसएच करने के बाद, आपके पास वीएम का ऐक्सेस होना चाहिए. आइए, Gemini CLI चलाने के लिए एक फ़ोल्डर बनाएं

mkdir antigravitycli && cd antigravitycli

3. Antigravity CLI इंस्टॉल करने के लिए, इसका इस्तेमाल करें

curl -fsSL https://antigravity.google/cli/install.sh | bash && source ~/.bashrc

वर्शन देखना

agy --version

4. आइए, लॉग इन करके इसकी पुष्टि करें, ताकि हम बाद में कुछ टेस्टिंग कर सकें.

agy

5. पहला विकल्प Google OAuth चुनें . अब पुष्टि करते हैं.
6. इसके बाद, https:// से शुरू होने वाले यूआरएल को कॉपी करें. अपने लैब ब्राउज़र की विंडो में एक नया टैब खोलें और यूआरएल चिपकाएं. प्रॉम्प्ट स्वीकार करें.

7. जब आपको यह दिखे, तो 'क्लिपबोर्ड पर कॉपी करें' को चुनें. इसके बाद, cli-vm सेशन पर वापस जाएं. Enter authorization code: के लिए, कॉपी किया गया कोड चिपकाएं और पुष्टि करने के लिए Enter दबाएं.

8. cli-vm वीएम सेशन पर वापस जाएं. इसके बाद, Enter authorization code: के लिए, कॉपी किया गया कोड चिपकाएं और पुष्टि करने के लिए Enter दबाएं.

9. आपको वह स्क्रीन दिखेगी जहां कानूनी समझौते को पसंद के मुताबिक बनाया जा सकता है और उसे स्वीकार किया जा सकता है. साथ ही, अपनी होम डायरेक्ट्री पर जाया जा सकता है. जानकारी देने के लिए, सही विकल्प चुनें.

10. इसे पूरा करने के बाद, Antigravity CLI का इस्तेमाल शुरू किया जा सकता है

ध्यान दें: प्रॉम्प्ट के सवाल को किसी और सवाल में बदला जा सकता है.

मॉनिटर वीएम के ज़रिए, Gemini पर जाने वाले ट्रैफ़िक के रूट पर नज़र रखना

1. वीएम इंस्टेंस पर जाएं. monitor-vm से शुरू होने वाली वीएम को चुनें. एसएसएच चुनें.
2. monitor-vm में एसएसएच करने के बाद, आपके पास ऐक्सेस होना चाहिए
3. आइए, dig कमांड का इस्तेमाल करके, Gemini API से कनेक्ट करने के पाथ की जांच करें. हम us-east1-aiplatform.googleapis.com का इस्तेमाल करेंगे

dig us-east1-aiplatform.googleapis.com

आपको कुछ ऐसा दिखेगा. हालांकि, पता अलग होगा. ध्यान दें कि एपीआई एक सार्वजनिक एपीआई है. इसलिए, पाथ सार्वजनिक आईपी पतों के ज़रिए होता है.

कॉपी न करें

; <<>> DiG 9.18.33-1~deb12u2-Debian <<>> us-east1-aiplatform.googleapis.com
;; global options: +cmd
;; Got answer:
;; ->>HEADER<<- opcode: QUERY, status: NOERROR, id: 58905
;; flags: qr rd ra; QUERY: 1, ANSWER: 14, AUTHORITY: 0, ADDITIONAL: 1

;; OPT PSEUDOSECTION:
; EDNS: version: 0, flags:; udp: 65494
;; QUESTION SECTION:
;us-east1-aiplatform.googleapis.com. IN A

;; ANSWER SECTION:
us-east1-aiplatform.googleapis.com. 300 IN A    216.239.38.223
us-east1-aiplatform.googleapis.com. 300 IN A    216.239.34.223
us-east1-aiplatform.googleapis.com. 300 IN A    216.239.36.223
us-east1-aiplatform.googleapis.com. 300 IN A    216.239.32.223

4. अब ping टेस्ट करके देखते हैं कि Gemini API से कनेक्ट किया जा सकता है या नहीं. यह निर्देश, us-east1-aiplatform.googleapis.com को पिंग करने के लिए चार पिंग का इस्तेमाल करेगा. इससे हमें एपीआई के सार्वजनिक पते से जवाब मिलेगा.

ping -c 4 us-east1-aiplatform.googleapis.com

5. हम इस वीएम की जांच बाद में करेंगे. एसएसएच सेशन बंद करें और आगे बढ़ें.

6. टास्क 4. Terraform की मदद से, googleapis के लिए पीएससी एंडपॉइंट बनाना

Vertex API एंडपॉइंट से निजी तौर पर कनेक्ट करने की सुविधा चालू करने के लिए, हम Google API के लिए Private Service Connect एंडपॉइंट बनाएंगे. इससे हमें एक निजी आईपी पते का इस्तेमाल करने की अनुमति मिलेगी. हम इस पते को, Google के उन एपीआई पर ट्रैफ़िक भेजने के लिए असाइन करते हैं जिनकी हमें ज़रूरत होती है. इस मामले में, Vertex.

1. अगर Cloud Shell पहले से खुला नहीं है, तो उसे एडिटर व्यू में खोलें. हम ये चीज़ें बनाने जा रहे हैं:

• पीएसटी एंडपॉइंट 10.10.100.250 के लिए आईपी बनाएं (resource "google_compute_global_address" "default")
• Google API के लिए पीएससी एंडपॉइंट बनाएं (resource "google_compute_global_forwarding_rule" "default")

terraform-build फ़ोल्डर में मौजूद psc.tf फ़ाइल खोलें. फ़ाइल में यह कोड जोड़ें.

Terraform psc.tf

resource "google_compute_global_address" "default" {
  name         = "gemini-ip"
  purpose      = "PRIVATE_SERVICE_CONNECT"
  network      = google_compute_network.default.id
  address_type = "INTERNAL"
  address      = "10.10.100.250" 
}

resource "google_compute_global_forwarding_rule" "default" {  
  name                  = "pscgemini"
  target                = "all-apis"
  network               = google_compute_network.default.id
  ip_address            = google_compute_global_address.default.id 
  load_balancing_scheme = ""
  
  service_directory_registrations {
    namespace                = "googleapis"
    service_directory_region = "us-east1"
  }
}

2. Cloud Shell टर्मिनल पर स्विच करें और पक्का करें कि आप terraform-build फ़ोल्डर में हों. इसके बाद, terraform init चलाएं. इससे आपको पता चलेगा कि दो आइटम जोड़े जाएंगे.
   इसके बाद, terraform apply चलाएं और आईपी और पीएससी Google APIs एंडपॉइंट बनाने के लिए yes टाइप करें.terraform plan
3. एंडपॉइंट मौजूद होने की पुष्टि करना

gcloud compute addresses list --filter="name=( 'gemini-ip' ...)"

gcloud compute forwarding-rules describe pscgemini --global

7. टास्क 5. Terraform की मदद से, googleapis के लिए मैन्युअल डीएनएस एंट्री बनाना

निजी डीएनएस का इस्तेमाल करके, पीएससी एंडपॉइंट पर ले जाने के लिए, मैन्युअल डीएनएस एंट्री बनाई जा सकती है. इससे उन सभी नेटवर्क पर असर पड़ेगा जिन्हें आपने इससे असाइन किया है.

1. नेटवर्क सेवाओं पर जाएं और Cloud DNS चुनें.
2. आपको ज़ोन में, Google APIs के लिए Private Service Connect का अपने-आप बनाया गया ज़ोन दिखेगा. इसका ज़ोन टाइप, सेवा डायरेक्ट्री होगा. इसका इस्तेमाल, पीएससी एंडपॉइंट से कनेक्ट करने के लिए किया जा सकता है. इसका फ़ॉर्मैट **SERVICE-ENDPOINT.p.googleapis.com होता है. उदाहरण: aiplatform-pscgemini.p.googleapis.com
3. इस मामले में, हमें मैन्युअल तरीके से एक निजी डीएनएस एंट्री बनानी है. कॉन्फ़िगरेशन इस तरह होगा

• "googleapis.com" के लिए, "googleapis-private" नाम का एक निजी डीएनएस ज़ोन बनाएं और इसे "antigravity-vpc-net" नेटवर्क तक सीमित करें.
• "googleapis.com" को आईपी पते "10.10.100.250" पर मैप करने के लिए, एक A रिकॉर्ड जोड़ें.
• "googleapis.com" के सभी सबडोमेन (जैसे, www.googleapis.com) को "googleapis.com" पर रीडायरेक्ट करने के लिए, CNAME रिकॉर्ड जोड़ें.

4. अगर Cloud Shell पहले से खुला नहीं है, तो उसे एडिटर व्यू में खोलें. terraform-build फ़ोल्डर में मौजूद dns.tf फ़ाइल खोलें. फ़ाइल में यह कोड जोड़ें.

Terraform dns.tf

resource "google_dns_managed_zone" "private_zone" {
  name        = "googleapis-private"
  dns_name    = "googleapis.com."  
  visibility  = "private"
  project     = var.project_id     

  private_visibility_config {
    networks {
      network_url = google_compute_network.default.id  
    }
  }
}

resource "google_dns_record_set" "a_record" {
  name    = "googleapis.com."  
  type    = "A"
  ttl     = 300
  managed_zone = google_dns_managed_zone.private_zone.name
  project = var.project_id    

  rrdatas = ["10.10.100.250"]
}

resource "google_dns_record_set" "cname_record" {
 name    = "*.googleapis.com."
 type    = "CNAME"
 ttl     = 300
 managed_zone = google_dns_managed_zone.private_zone.name
 project = var.project_id    

 rrdatas = ["googleapis.com."]  
}

5. Cloud Shell टर्मिनल पर स्विच करें. पक्का करें कि आप terraform-build फ़ोल्डर में हों. इसके बाद, terraform plan चलाएं. इससे आपको पता चलेगा कि कौनसे आइटम जोड़े जाएंगे.
   इसके बाद, terraform apply चलाएं और निजी डीएनएस एंट्री बनाने के लिए yes टाइप करें.
6. आपको A रिकॉर्ड और CNAME वाला सेटअप ऐसा दिखना चाहिए

7. इसके बाद, हम monitor-vm पर इन बदलावों के साथ कनेक्टिविटी की पुष्टि करते हैं

8. टास्क 7. आईपी पते के ज़रिए एंडपॉइंट कनेक्टिविटी की पुष्टि करना

Gemini से कनेक्ट करने के लिए, प्राइवेट एंडपॉइंट का इस्तेमाल करें.

ध्यान दें: वीएम पर मैन्युअल तरीके से कोई कॉन्फ़िगरेशन करना ज़रूरी नहीं है. हम monitor-vm का इस्तेमाल कर रहे हैं

1. VM इंस्टेंस monitor-vm पर जाएं. एसएसएच चुनें और वीएम में एसएसएच करें
2. ping कमांड का इस्तेमाल करके, us-east1-aiplatform.googleapis.com से कनेक्टिविटी का पाथ देखें. इससे, निजी डीएनएस में मौजूद आईपी पते को पिंग किया जाएगा. साथ ही, googleapis के लिए A रिकॉर्ड को भी पिंग किया जाएगा. यह आईपी, पीएससी एंडपॉइंट है. इसलिए, आपके पिंग पूरे नहीं हो पाएंगे.

ping -c 2 us-east1-aiplatform.googleapis.com

3. dig कमांड का इस्तेमाल करके, us-east1-aiplatform.googleapis.com से कनेक्टिविटी का पाथ देखें. यह पीएससी एंडपॉइंट (10.10.100.250) का आईपी पता होना चाहिए.

dig us-east1-aiplatform.googleapis.com

4. यह प्रोसेस पूरी होने के बाद, monitor-vm SSH सेशन बंद किया जा सकता है.

हम **cli-vm** पर स्विच कर रहे हैं

5. VM इंस्टेंस cli-vm पर जाएं. एसएसएच चुनें और वीएम में एसएसएच करें
6. अब हम cli-vm पर टीसीपी डंप चला सकते हैं. हमें एक ही वीएम के लिए दो एसएसएच सेशन खोलने होंगे. एक सेशन में tcpdump कमांड चलेगी, जबकि दूसरे में हम Gemini के सीएलआई का इस्तेमाल करेंगे.
7. tcpdump में कनेक्टिविटी देखने के लिए, यह कमांड टाइप करें

sudo tcpdump -i any port 53 -n or host us-east1-aiplatform.googleapis.com

8. अब cli-vm पर अगले सेशन में एसएसएच करें
9. antigravitycli फ़ोल्डर cd antigravitycli पर जाएं
10. agy टाइप करके, Antigravity CLI को चालू करें
11. यह सवाल पूछें; what color is the sky? Gemini API को कॉल करने के लिए

12. इसे चलाने और नतीजा देखने के लिए, enter दबाएं.
13. cli-vm पर पहले सेशन पर वापस जाएं. आपको tcpdump का नतीजा दिखेगा. आपको दिखेगा कि वीएम का आईपी पता, Gemini API से कनेक्ट करने के लिए पीएससी एंडपॉइंट के आईपी पते का इस्तेमाल कर रहा है

VM इंस्टेंस के सभी SSH सेशन बंद करें

9. क्लीन अप करें

1. Cloud Shell पर जाएं. पक्का करें कि आप terraform-build डायरेक्ट्री cd terraform-build में हों. इसके बाद, यह कमांड terraform destroy चलाएं और yes टाइप करें. इससे, आपके प्रोजेक्ट में Terraform की मदद से बनाए गए सभी संसाधन हटा दिए जाएंगे.

10. बधाई हो

बधाई हो! आपने सार्वजनिक एपीआई पते और Google API के लिए Private Service Connect एंडपॉइंट का इस्तेमाल करके, Antigravity CLI से कनेक्ट कर लिया है. इस सुविधा की मदद से, प्राइवेट एपीआई कनेक्टिविटी को अपने ऑन-प्रेम/अन्य क्लाउड एनवायरमेंट में बढ़ाया जा सकता है. ये एनवायरमेंट, इंटरकनेक्ट, क्रॉस-क्लाउड इंटरकनेक्ट, और वीपीसी के ज़रिए कनेक्ट किए जाते हैं.

अगले चरण / ज़्यादा जानें

ज़्यादा जानकारी के लिए, Antigravity सीएलआई के दस्तावेज़ पढ़ें

अगली लैब पर जाएं

Google Cloud के साथ अपनी क्वेस्ट जारी रखें. साथ ही, Google Cloud के इन अन्य लैब को आज़माएं:

• Google Cloud में नेटवर्किंग की बुनियादी बातें
• जनरेटिव एआई एक्सप्लोरर - Vertex AI
• Cloud Networking की खास जानकारी