এই পৃষ্ঠাটি Cloud Translation API অনুবাদ করেছে।

Google ক্লাউডের জন্য ABAP SDK ব্যবহার করে SAP-এ BigQuery ML পূর্বাভাস পড়ুন

১. ভূমিকা

এই কোডল্যাবে, আপনি BigQuery- তে একটি মেশিন লার্নিং (ML) মডেল তৈরি করবেন এবং Google Cloud-এর জন্য ABAP SDK ব্যবহার করে এই মডেল থেকে প্রেডিকশন পাবেন।

আপনি নিম্নলিখিত গুগল ক্লাউড পরিষেবাগুলি ব্যবহার করবেন:

বিগকোয়েরি
ক্লাউড শেল

আপনি যা তৈরি করবেন

আপনি নিম্নলিখিতগুলি তৈরি করবেন:

একটি BigQuery মেশিন লার্নিং (ML) মডেল।
BigQuery API কল করার জন্য BigQuery Job User রোল সহ একটি সার্ভিস অ্যাকাউন্ট।
BigQuery API কল করে ML মডেল থেকে প্রেডিকশন পাওয়ার জন্য একটি ABAP প্রোগ্রাম।

২. প্রয়োজনীয়তা

একটি ব্রাউজার, যেমন ক্রোম বা ফায়ারফক্স ।
বিলিং চালু সহ একটি গুগল ক্লাউড প্রজেক্ট অথবা গুগল ক্লাউড প্ল্যাটফর্মের জন্য একটি ৯০-দিনের ফ্রি ট্রায়াল অ্যাকাউন্ট তৈরি করুন ।
আপনার সিস্টেমে SAP GUI (উইন্ডোজ বা জাভা) ইনস্টল করা থাকতে হবে। যদি আপনার ল্যাপটপে SAP GUI আগে থেকেই ইনস্টল করা থাকে, তাহলে অ্যাপ্লিকেশন সার্ভার আইপি হিসেবে ভিএম এক্সটার্নাল আইপি অ্যাড্রেস ব্যবহার করে SAP-এর সাথে সংযোগ করুন। আপনি যদি ম্যাক ব্যবহার করেন, তাহলে এই লিঙ্কে উপলব্ধ SAP GUI for Java-ও ইনস্টল করতে পারেন।

৩. শুরু করার আগে

গুগল ক্লাউড কনসোলের প্রজেক্ট সিলেক্টর পেজে, একটি গুগল ক্লাউড প্রজেক্ট নির্বাচন করুন বা তৈরি করুন (উদাহরণস্বরূপ: abap-sdk-poc )।
আপনার ক্লাউড প্রোজেক্টের জন্য বিলিং চালু আছে কিনা তা নিশ্চিত করুন। কোনো প্রোজেক্টে বিলিং চালু আছে কিনা তা কীভাবে পরীক্ষা করবেন তা জানুন। আপনি যদি ৯০-দিনের ফ্রি ট্রায়াল অ্যাকাউন্ট ব্যবহার করেন, তাহলে এই ধাপটি এড়িয়ে যান।
আপনি গুগল ক্লাউডে চালিত একটি কমান্ড-লাইন পরিবেশ, ক্লাউড শেল ব্যবহার করবেন।
ক্লাউড কনসোল থেকে, উপরের ডান কোণায় থাকা ‘Activate Cloud Shell’-এ ক্লিক করুন:

আপনার অ্যাকাউন্টে প্রমাণীকরণ করতে এবং ডিফল্ট প্রজেক্ট abap-sdk-poc এ সেট করতে ক্লাউড শেলে নিম্নলিখিত কমান্ডগুলি চালান। উদাহরণস্বরূপ us-west4-b জোনটি ব্যবহার করা হয়েছে। প্রয়োজন হলে, আপনার পছন্দ অনুযায়ী নিম্নলিখিত কমান্ডগুলিতে প্রজেক্ট এবং জোন পরিবর্তন করুন।

gcloud auth login
gcloud config set project abap-sdk-poc
gcloud config set compute/zone us-west4-b

আপনার এমন একটি SAP সিস্টেমে অ্যাক্সেস থাকতে হবে যেখানে Google Cloud-এর জন্য ABAP SDK ইনস্টল করা আছে।
এই কোডল্যাবটি শুরু করার আগে আপনাকে অবশ্যই কোডল্যাব ১ ( গুগল ক্লাউড প্ল্যাটফর্মে এবিএপি প্ল্যাটফর্ম ট্রায়াল ১৯০৯ ইনস্টল করা এবং গুগল ক্লাউডের জন্য এবিএপি এসডিকে ইনস্টল করা) এবং কোডল্যাব ২ ( কম্পিউট ইঞ্জিন ভিএম-এ হোস্ট করা এসএপি-এর জন্য টোকেন ব্যবহার করে এবিএপি এসডিকে অথেনটিকেশন কনফিগার করা ) সম্পন্ন করতে হবে।
যদি আপনি কোডল্যাব ১ এবং কোডল্যাব ২ সম্পন্ন করে থাকেন, তাহলে আপনাকে গুগল ক্লাউডে একটি এবিএপি প্ল্যাটফর্ম ট্রায়াল ১৯০৯ সিস্টেম প্রদান করা হয়েছে, সাথে অথেনটিকেশন এবং কানেক্টিভিটির জন্য প্রয়োজনীয় সেটআপও দেওয়া হয়েছে।
যদি আপনি কোডল্যাব ১ এবং কোডল্যাব ২ সম্পন্ন না করে থাকেন, তাহলে এই কোডল্যাবে প্রদত্ত ধাপগুলো সম্পাদন করার জন্য আপনার কাছে প্রয়োজনীয় সমস্ত পরিকাঠামো এবং সংযোগ থাকবে না। অতএব, এই কোডল্যাবটি নিয়ে অগ্রসর হওয়ার আগে আপনাকে অবশ্যই কোডল্যাব ১ এবং কোডল্যাব ২ সম্পন্ন করতে হবে।

৪. আপনার গুগল ক্লাউড প্রজেক্টে BigQuery API V2 সক্রিয় করুন।

ক্লাউড কনসোল থেকে, উপরের ডান কোণায় থাকা ‘Activate Cloud Shell’-এ ক্লিক করুন:

BigQuery API সক্রিয় করতে Cloud Shell-এ নিম্নলিখিত কমান্ডগুলি চালান:

gcloud services enable bigquery.googleapis.com

সফলভাবে কার্যকর হলে আপনি নীচে দেখানো বার্তাটি দেখতে পাবেন।

এখন আপনার গুগল ক্লাউড প্রজেক্টে BigQuery API সক্রিয় করা থাকা উচিত।

৫. সুরক্ষিত BigQuery অ্যাক্সেসের জন্য একটি সার্ভিস অ্যাকাউন্ট তৈরি করুন

BigQuery ML মডেল থেকে নিরাপদে ML প্রেডিকশন পেতে, আপনাকে BigQuery Job User এবং BigQuery Data Viewer রোলসহ একটি সার্ভিস অ্যাকাউন্ট তৈরি করতে হবে। এটি আপনার প্রোগ্রামকে প্রোজেক্টের মধ্যে কোয়েরি (জব হিসেবে) চালাতে এবং টেবিল থেকে ডেটা পড়তে অনুমতি দেবে। এই রোলটি শুধুমাত্র জব তৈরি এবং ডেটা পড়ার জন্য প্রয়োজনীয় অনুমতি প্রদান করে, যা নিরাপত্তা ঝুঁকি কমিয়ে আনে।

একটি পরিষেবা অ্যাকাউন্ট তৈরি করুন

প্রয়োজনীয় ভূমিকা সহ একটি পরিষেবা অ্যাকাউন্ট তৈরি করতে, নিম্নলিখিত ধাপগুলি অনুসরণ করুন:

ক্লাউড শেল টার্মিনালে নিম্নলিখিত কমান্ডটি চালান:

gcloud iam service-accounts create abap-sdk-bigquery-jobuser --display-name="Service Account for BigQuery Job user"

এখন পূর্ববর্তী ধাপে তৈরি করা সার্ভিস অ্যাকাউন্টে প্রয়োজনীয় রোলগুলো যোগ করুন:

gcloud projects add-iam-policy-binding abap-sdk-poc --member='serviceAccount:abap-sdk-bigquery-jobuser@abap-sdk-poc.iam.gserviceaccount.com' --role='roles/bigquery.jobUser'

gcloud projects add-iam-policy-binding abap-sdk-poc --member='serviceAccount:abap-sdk-bigquery-jobuser@abap-sdk-poc.iam.gserviceaccount.com' --role='roles/bigquery.dataViewer'

উপরের কমান্ডটি গুগল ক্লাউড প্রজেক্টের জন্য প্লেসহোল্ডার হিসেবে abap-sdk-poc ব্যবহার করে। abap-sdk-poc জায়গায় আপনার প্রজেক্ট আইডি বসান।

রোলটি যোগ করা হয়েছে কিনা তা যাচাই করতে, IAM পেজে যান। আপনার তৈরি করা সার্ভিস অ্যাকাউন্টটি, সেটিতে নির্ধারিত রোলসহ তালিকাভুক্ত থাকা উচিত।

৬. একটি BigQuery মেশিন লার্নিং মডেল তৈরি করা

এই কোডল্যাবে, আমরা লন্ডন বাইসাইকেল ভাড়ার ডেটাসেটকে ক্লাস্টার করার জন্য একটি কে-মিনস মডেল তৈরি করব। আপনি আপনার ডেটাকে ক্লাস্টারে ভাগ করার জন্য কে-মিনস অ্যালগরিদম প্রয়োগ করতে পারেন। সুপারভাইজড মেশিন লার্নিং, যা প্রেডিক্টিভ অ্যানালিটিক্স নিয়ে কাজ করে, তার থেকে ভিন্ন, আনসুপারভাইজড লার্নিং হলো ডেসক্রিপটিভ অ্যানালিটিক্স। এর মূল উদ্দেশ্য হলো আপনার ডেটা বোঝা, যাতে আপনি ডেটার উপর ভিত্তি করে সিদ্ধান্ত নিতে পারেন।

আপনার ডেটাসেট তৈরি করুন

আপনার এমএল মডেল সংরক্ষণের জন্য একটি BigQuery ডেটাসেট তৈরি করতে, নিম্নলিখিত ধাপগুলি অনুসরণ করুন:

Google Cloud কনসোলে, BigQuery পৃষ্ঠায় যান। BigQuery পৃষ্ঠায় যান
এক্সপ্লোরার প্যানে আপনার প্রজেক্টের নামে ক্লিক করুন।
ক্লিক করুন কার্যকলাপসমূহ দেখুন > ডেটাসেট তৈরি করুন ।

ডেটা সেট তৈরি করার পৃষ্ঠায়, নিম্নলিখিতগুলি করুন:

ডেটা সেট আইডি-র জন্য, bqml_tutorial লিখুন।
লোকেশন টাইপের জন্য, মাল্টি-রিজিওন নির্বাচন করুন এবং তারপরে ইইউ (ইউরোপীয় ইউনিয়নের একাধিক অঞ্চল) নির্বাচন করুন। লন্ডন বাইসাইকেল হায়ারস পাবলিক ডেটাসেটটি ইইউ মাল্টি-রিজিওনে সংরক্ষিত আছে। আপনার ডেটাসেটটিও অবশ্যই একই লোকেশনে থাকতে হবে।
বাকি ডিফল্ট সেটিংস অপরিবর্তিত রেখে, 'Create dataset'-এ ক্লিক করুন।

একটি কে-মিনস মডেল তৈরি করুন

এখন যেহেতু আপনার ডেটাসেট তৈরি হয়ে গেছে, পরবর্তী ধাপ হলো এই ডেটা ব্যবহার করে একটি কে-মিনস মডেল তৈরি করা। আপনি model_type=kmeans অপশনটিসহ ` CREATE MODEL` স্টেটমেন্ট ব্যবহার করে একটি কে-মিনস মডেল তৈরি ও প্রশিক্ষণ দিতে পারেন।

কোয়েরিটি রান করতে এবং একটি কে-মিনস মডেল তৈরি করতে, নিম্নলিখিত ধাপগুলো অনুসরণ করুন:

BigQuery পৃষ্ঠায় যান। BigQuery-তে যান।
এডিটর প্যানে, নিম্নলিখিত SQL স্টেটমেন্টটি চালান:

CREATE OR REPLACE MODEL `bqml_tutorial.london_station_clusters`
  OPTIONS(model_type='kmeans', num_clusters=4) AS
WITH
  hs AS (
  SELECT
    h.start_station_name AS station_name,
  IF
    (EXTRACT(DAYOFWEEK
      FROM
        h.start_date) = 1
      OR EXTRACT(DAYOFWEEK
      FROM
        h.start_date) = 7,
      "weekend",
      "weekday") AS isweekday,
    h.duration,
    ST_DISTANCE(ST_GEOGPOINT(s.longitude,
        s.latitude),
      ST_GEOGPOINT(-0.1,
        51.5))/1000 AS distance_from_city_center
  FROM
    `bigquery-public-data.london_bicycles.cycle_hire` AS h
  JOIN
    `bigquery-public-data.london_bicycles.cycle_stations` AS s
  ON
    h.start_station_id = s.id
  WHERE
    h.start_date BETWEEN CAST('2015-01-01 00:00:00' AS TIMESTAMP)
    AND CAST('2016-01-01 00:00:00' AS TIMESTAMP) ),
  stationstats AS (
  SELECT
    station_name,
    isweekday,
    AVG(duration) AS duration,
    COUNT(duration) AS num_trips,
    MAX(distance_from_city_center) AS distance_from_city_center
  FROM
    hs
  GROUP BY
    station_name, isweekday)
SELECT
  * EXCEPT(station_name, isweekday)
FROM
  stationstats

ন্যাভিগেশন প্যানেলের রিসোর্সেস (Resources) সেকশনে, আপনার প্রোজেক্টের নামটি এক্সপ্যান্ড করুন, bqml_tutorial-এ ক্লিক করুন এবং তারপরে london_station_clusters-এ ক্লিক করুন।
স্কিমা ট্যাবে ক্লিক করুন। মডেল স্কিমাতে তিনটি স্টেশন অ্যাট্রিবিউটের তালিকা থাকে, যেগুলো BigQuery ML ক্লাস্টারিং করার জন্য ব্যবহার করেছে। স্কিমাটি দেখতে নিচের মতো হওয়া উচিত:

ইভ্যালুয়েশন ট্যাবে ক্লিক করুন। এই ট্যাবটি কে-মিনস মডেল দ্বারা চিহ্নিত ক্লাস্টারগুলির ভিজ্যুয়ালাইজেশন প্রদর্শন করে। নিউমেরিক ফিচারস-এর অধীনে, বার গ্রাফ প্রতিটি সেন্ট্রয়েডের জন্য ১০টি পর্যন্ত সবচেয়ে গুরুত্বপূর্ণ নিউমেরিক ফিচার ভ্যালু প্রদর্শন করে। আপনি ড্রপ-ডাউন মেনু থেকে কোন ফিচারগুলো ভিজ্যুয়ালাইজ করবেন তা নির্বাচন করতে পারেন।

৭. গুগল ক্লাউডের জন্য এবিএপি এসডিকে ব্যবহার করে বিগকোয়েরি এমএল প্রেডিকশন পান।

এখন যেহেতু আপনি গুগল ক্লাউডের দিকে পূর্বশর্তগুলো সেট আপ করে ফেলেছেন, আপনি গুগল ক্লাউডের জন্য এবিএপি এসডিকে (ABAP SDK for Google Cloud) ব্যবহার করে এমএল মডেল থেকে পূর্বাভাস পাওয়ার জন্য আপনার এসএপি (SAP) সিস্টেমের ধাপগুলো সম্পন্ন করতে প্রস্তুত।

ক্লায়েন্ট কী কনফিগারেশন তৈরি করুন

প্রমাণীকরণ এবং সংযোগ-সম্পর্কিত কনফিগারেশনের জন্য, গুগল ক্লাউডের জন্য এবিএপি এসডিকে (ABAP SDK for Google Cloud /GOOG/CLIENT_KEY এবং /GOOG/SERVIC_MAP.

/GOOG/CLIENT_KEY টেবিলের কনফিগারেশন বজায় রাখতে, নিম্নলিখিত ধাপগুলি অনুসরণ করুন:

SAP GUI-তে, SPRO ট্রানজ্যাকশন কোডটি প্রবেশ করান।
SAP রেফারেন্স IMG-তে ক্লিক করুন।
Google Cloud-এর জন্য ABAP SDK-তে ক্লিক করুন > মৌলিক সেটিংস > ক্লায়েন্ট কী কনফিগার করুন

তালিকাভুক্ত ক্ষেত্রগুলিতে নিম্নলিখিত মানগুলি বজায় রাখুন, অন্য সব ক্ষেত্র খালি রাখুন:

মাঠ	মূল্য
গুগল ক্লাউড কী নাম	বিগকোয়েরি_এমএল
গুগল ক্লাউড পরিষেবা অ্যাকাউন্টের নাম	abap-sdk-bigquery-jobuser@abap-sdk-poc.iam.gserviceaccount.com
গুগল ক্লাউড স্কোপ	https://www.googleapis.com/auth/cloud-platform
প্রকল্প আইডি	abap-sdk-poc
অনুমোদন শ্রেণী	/GOOG/CL_AUTH_GOOGLE

BigQuery ML মডেল থেকে পূর্বাভাস পেতে একটি ABAP রিপোর্ট তৈরি করুন।

একটি ABAP রিপোর্ট তৈরি করতে, নিম্নলিখিত ধাপগুলি অনুসরণ করুন:

আপনার SAP GUI-তে, SE38 ট্রানজ্যাকশন কোডে যান এবং ZDEMO_BIGQUERY_ML_PREDICT.
যে পপ-আপটি খুলে যাবে, সেখানে নিচের ছবিতে দেখানো অনুযায়ী বিবরণ দিন:

পরবর্তী পপ-আপে, প্রয়োজন অনুযায়ী লোকাল অবজেক্ট নির্বাচন করুন অথবা একটি প্যাকেজের নাম প্রদান করুন।
ABAP এডিটরে নিম্নলিখিত কোডটি যোগ করুন:

REPORT zdemo_bigquery_ml_predict.

types:
  begin of lty_query_result,
    centroid_id     type i,
    station_name    type string,
    isweekday       type string,
    num_trips       type i,
    distance_from_city type string,
  end of lty_query_result,
  ltt_query_result type standard table of lty_query_result.

DATA:
  lv_project_id TYPE string,
  ls_input      TYPE /goog/cl_bigquery_v2=>ty_103,
  ls_output     TYPE lty_query_result,
  lt_output     TYPE ltt_query_result.

CONSTANTS:
  lc_newline TYPE c VALUE cl_abap_char_utilities=>newline.

TRY.
    "Initialize Bigquery object, pass the client key name that you have configured in /GOOG/CLIENT_KEY table
    DATA(lo_bq) = NEW /goog/cl_bigquery_v2( iv_key_name = 'BIGQUERY_ML' ).

    "Populate relevant parameters
    lv_project_id = lo_bq->gv_project_id.

    ls_input-default_dataset-project_id = 'abap-sdk-poc'.
    ls_input-default_dataset-dataset_id = 'bqml_tutorial'.

    "This query gets predictions from
    ls_input-query =
                | WITH | && lc_newline &&
                | hs AS ( | && lc_newline &&
                | SELECT | && lc_newline &&
                | h.start_station_name AS station_name, | && lc_newline &&
                | IF | && lc_newline &&
                | (EXTRACT(DAYOFWEEK | && lc_newline &&
                | FROM | && lc_newline &&
                | h.start_date) = 1 | && lc_newline &&
                | OR EXTRACT(DAYOFWEEK | && lc_newline &&
                | FROM | && lc_newline &&
                | h.start_date) = 7, | && lc_newline &&
                | "weekend", | && lc_newline &&
                | "weekday") AS isweekday, | && lc_newline &&
                | h.duration, | && lc_newline &&
                | ST_DISTANCE(ST_GEOGPOINT(s.longitude, | && lc_newline &&
                | s.latitude), | && lc_newline &&
                | ST_GEOGPOINT(-0.1, | && lc_newline &&
                | 51.5))/1000 AS distance_from_city_center | && lc_newline &&
                | FROM | && lc_newline &&
                | `bigquery-public-data.london_bicycles.cycle_hire` AS h | && lc_newline &&
                | JOIN | && lc_newline &&
                | `bigquery-public-data.london_bicycles.cycle_stations` AS s | && lc_newline &&
                | ON | && lc_newline &&
                | h.start_station_id = s.id | && lc_newline &&
                | WHERE | && lc_newline &&
                | h.start_date BETWEEN CAST('2015-01-01 00:00:00' AS TIMESTAMP) | && lc_newline &&
                | AND CAST('2016-01-01 00:00:00' AS TIMESTAMP) ), | && lc_newline &&
                | stationstats AS ( | && lc_newline &&
                | SELECT | && lc_newline &&
                | station_name, | && lc_newline &&
                | isweekday, | && lc_newline &&
                | AVG(duration) AS duration, | && lc_newline &&
                | COUNT(duration) AS num_trips, | && lc_newline &&
                | MAX(distance_from_city_center) AS distance_from_city_center | && lc_newline &&
                | FROM | && lc_newline &&
                | hs | && lc_newline &&
                | GROUP BY | && lc_newline &&
                | station_name, isweekday ) | && lc_newline &&
                | SELECT | && lc_newline &&
                | * EXCEPT(nearest_centroids_distance) | && lc_newline &&
                | FROM | && lc_newline &&
                | ML.PREDICT( MODEL `bqml_tutorial.london_station_clusters`, | && lc_newline &&
                | ( | && lc_newline &&
                | SELECT | && lc_newline &&
                | * | && lc_newline &&
                | FROM | && lc_newline &&
                | stationstats | && lc_newline &&
                | WHERE | && lc_newline &&
                | REGEXP_CONTAINS(station_name, 'Kennington'))) |.

    "Call API method: bigquery.jobs.query
    CALL METHOD lo_bq->query_jobs
      EXPORTING
        iv_p_project_id = lv_project_id
        is_input        = ls_input
      IMPORTING
        es_output       = DATA(ls_response)
        ev_ret_code     = DATA(lv_ret_code)
        ev_err_text     = DATA(lv_err_text)
        es_err_resp     = DATA(ls_err_resp).

    IF lo_bq->is_success( lv_ret_code ).
      "API Call successful, loop through the data & display the result
      IF ls_response-job_complete = abap_true.
        LOOP AT ls_response-rows ASSIGNING FIELD-SYMBOL(<ls_row>).
          LOOP AT <ls_row>-f ASSIGNING FIELD-SYMBOL(<ls_value>).
            ASSIGN <ls_value>-v->* TO FIELD-SYMBOL(<ls_field_value>).
            CASE sy-tabix.
              WHEN 1.
                ls_output-centroid_id = <ls_field_value>.
              WHEN 2.
                ls_output-station_name = <ls_field_value>.
              WHEN 3.
                ls_output-isweekday = <ls_field_value>.
              WHEN 4.
                ls_output-num_trips = <ls_field_value>.
              WHEN 5.
                ls_output-distance_from_city = <ls_field_value>.
            ENDCASE.
          ENDLOOP.
          APPEND ls_output TO lt_output.
          CLEAR ls_output.
        ENDLOOP.
        IF lt_output IS NOT INITIAL.
          cl_demo_output=>new( )->begin_section( 'ML.Predict Query Details'
                               )->write_text( ls_input-query
                               )->write_text( 'Dataset: bigquery-public-data.london_bicycles'
                               )->end_section(
                               )->begin_section( 'ML.Predict Query Results'
                               )->write_data( lt_output
                               )->end_section(
                               )->display( ).
        ENDIF.
      ENDIF.
    ELSE.
      "Display error message in case the API call fails
      MESSAGE lv_err_text TYPE 'E'.
    ENDIF.

    "Close HTTP Connection
    lo_bq->close( ).

  CATCH /goog/cx_sdk INTO DATA(lo_exception).
    MESSAGE lo_exception->get_text( ) TYPE 'E'.
ENDTRY.

রিপোর্টটি সংরক্ষণ ও সক্রিয় করুন।
রিপোর্টটি চালান (F8)।

সফলভাবে কার্যকর হলে, আপনি নিচে দেখানো প্রতিবেদনের মতো একটি আউটপুট দেখতে পাবেন:

৮. অভিনন্দন

"ABAP SDK for Google Cloud ব্যবহার করে BigQuery মেশিন লার্নিং (ML) মডেল থেকে প্রেডিকশন পাওয়া" কোডল্যাবটি সম্পন্ন করার জন্য চমৎকার কাজ!

আপনি আপনার SAP সিস্টেমের ভেতর থেকেই একটি BigQuery মেশিন লার্নিং মডেলের পূর্বাভাস সফলভাবে সংগ্রহ করেছেন! আপনি ABAP এবং Google Cloud Services-এর মধ্যে ইন্টিগ্রেশনের একটি নতুন স্তর উন্মোচন করেছেন। Google Cloud-এর জন্য অন্যান্য আকর্ষণীয় ABAP SDK কোডল্যাবগুলির মাধ্যমে আপনার দিগন্ত প্রসারিত করুন:

গুগল ক্লাউডের জন্য এবিএপি এসডিকে-এর সাথে ট্রান্সলেশন এপিআই ব্যবহার করা
চাংকিং ব্যবহার করে ক্লাউড স্টোরেজ বাকেটে একটি বড় অবজেক্ট আপলোড করুন
গুগল ক্লাউডের জন্য এবিএপি এসডিকে ব্যবহার করে সিক্রেট ম্যানেজার থেকে ক্রেডেনশিয়াল/সিক্রেট পুনরুদ্ধার করা
ABAP থেকে Vertex AI টেস্ট-বাইসনকে কল করুন

৯. পরিষ্কার করুন

আপনি যদি গুগল ক্লাউডের জন্য এবিএপি এসডিকে (ABAP SDK for Google Cloud) সম্পর্কিত অতিরিক্ত কোডল্যাবগুলো নিয়ে আর কাজ চালিয়ে যেতে না চান, তবে অনুগ্রহ করে পরিষ্করণ প্রক্রিয়াটি সম্পন্ন করুন।

প্রকল্পটি মুছে ফেলুন

সতর্কতা : একটি প্রজেক্ট মুছে ফেলার নিম্নলিখিত প্রভাব রয়েছে:

প্রজেক্টের সবকিছু মুছে ফেলা হবে। আপনি যদি এই ডকুমেন্টের কাজগুলোর জন্য কোনো বিদ্যমান প্রজেক্ট ব্যবহার করে থাকেন, তবে সেটি মুছে ফেলার সাথে সাথে প্রজেক্টটিতে করা আপনার অন্য সব কাজও মুছে যাবে।
কাস্টম প্রজেক্ট আইডি হারিয়ে গেছে। এই প্রজেক্টটি তৈরি করার সময়, আপনি হয়তো একটি কাস্টম প্রজেক্ট আইডি তৈরি করেছিলেন যা আপনি ভবিষ্যতে ব্যবহার করতে চান। প্রজেক্ট আইডি ব্যবহার করে এমন URL-গুলো, যেমন appspot.com URL, সংরক্ষণ করতে, পুরো প্রজেক্টটি মুছে ফেলার পরিবর্তে প্রজেক্টের ভেতর থেকে নির্বাচিত রিসোর্সগুলো মুছে ফেলুন।

আপনি যদি একাধিক আর্কিটেকচার, টিউটোরিয়াল বা কুইকস্টার্ট অন্বেষণ করার পরিকল্পনা করেন, তবে প্রজেক্ট পুনঃব্যবহার আপনাকে প্রজেক্ট কোটার সীমা অতিক্রম করা এড়াতে সাহায্য করতে পারে।

গুগল ক্লাউড প্রজেক্টটি মুছে ফেলুন:

gcloud projects delete abap-sdk-poc

স্বতন্ত্র সম্পদ মুছে ফেলুন

কম্পিউট ইনস্ট্যান্সটি মুছে ফেলুন:

gcloud compute instances delete abap-trial-docker

ফায়ারওয়াল-রুলগুলো মুছে ফেলুন:

gcloud compute firewall-rules delete sapmachine

পরিষেবা অ্যাকাউন্টটি মুছে ফেলুন:

gcloud iam service-accounts delete \
    abap-sdk-bigquery-jobuser@abap-sdk-poc.iam.gserviceaccount.com