Получите событие из Cloud Pub/Sub в SAP с помощью ABAP SDK для Google Cloud.

1. Введение

В этой лабораторной работе вы научитесь получать информацию о событиях из темы Google Cloud Pub/Sub с помощью ABAP SDK для Google Cloud . Мы будем использовать следующие сервисы Google Cloud:

• Облачный Pub/Sub
• Cloud Shell

Предпосылки

• Убедитесь, что у вас есть доступ к системе SAP с установленным ABAP SDK для Google Cloud.
• Для настройки новой системы вы можете обратиться к практическому занятию « Установка пробной версии платформы ABAP на Google Cloud Platform и установка ABAP SDK ».
• Вы создали тему PUBSUB_DEMO_TOPIC в рамках практической работы « Отправка событий из SAP в Pub/Sub с помощью ABAP SDK » в вашем проекте Google Cloud. Если она ещё не создана, создайте её с помощью команды ниже:

gcloud pubsub topics create PUBSUB_DEMO_TOPIC

Что вы построите

Вам предстоит создать следующее:

• Учетная запись службы с правами «Подписчик» для взаимодействия с API Pub/Sub.
• Программа ABAP для получения и подтверждения сообщений из вашей темы Pub/Sub.

2. Требования

• Браузеры, такие как Chrome или Firefox .
• Проект Google Cloud с включенным биллингом или создание 90-дневной бесплатной пробной учетной записи для Google Cloud Platform.
• SAP GUI (Windows или Java) установлен в вашей системе. Если SAP GUI уже установлен на вашем ноутбуке, подключитесь к SAP, используя внешний IP-адрес виртуальной машины в качестве IP-адреса сервера приложений. Если вы используете Mac, вы также можете установить SAP GUI для Java, доступный по этой ссылке.

3. Прежде чем начать

• В Google Cloud Console на странице выбора проекта выберите или создайте проект Google Cloud (например: abap-sdk-poc ).
• Убедитесь, что для вашего облачного проекта включена оплата. Узнайте, как проверить, включена ли оплата для проекта . Пропустите этот шаг, если вы используете 90-дневную бесплатную пробную версию .
• Вы будете использовать Cloud Shell — среду командной строки, работающую в Google Cloud. В консоли Cloud Console нажмите «Активировать Cloud Shell» в правом верхнем углу:

• Выполните следующие команды для аутентификации вашей учётной записи и установите проект по умолчанию abap-sdk-poc . Зона us-west4-b используется в качестве примера. При необходимости измените проект и зону в следующих командах по своему усмотрению.

gcloud auth login
gcloud config set project abap-sdk-poc
gcloud config set compute/zone us-west4-b

• В рамках предыдущей лабораторной работы « Отправка события в Pub/Sub » вы уже должны были включить API Pub/Sub , создать тему и опубликовать сообщения в Pub/Sub.

4. Создайте учетную запись службы для доступа Pub/Sub.

Использование учётной записи службы с ролью Subscriber — самый безопасный способ получения сообщений от Pub/Sub вашей ABAP-программой. Эта роль ограничивает разрешения только получением сообщений, предотвращая потенциальные уязвимости безопасности.

Создайте учетную запись службы

Чтобы создать учетную запись службы с необходимой ролью, выполните следующие действия:

1. Выполните следующую команду в терминале Cloud Shell:

gcloud iam service-accounts \
create abap-sdk-pubsub-subscriber \
--display-name="Service Account for Pub/Sub Subscriber"

Примечание: при успешном выполнении вышеуказанной команды вы должны получить следующий ответ:

Создана учетная запись службы [abap-sdk-pubsub-subscriber].

2. Теперь добавьте необходимые роли в учетную запись службы, созданную на предыдущем шаге:

gcloud projects add-iam-policy-binding abap-sdk-poc \
--member='serviceAccount:[e-mail]' \
--role='roles/pubsub.subscriber'

Приведённая выше команда использует abap-sdk-poc в качестве заполнителя для проекта Google Cloud. Замените abap-sdk-poc идентификатором вашего проекта.

3. Чтобы убедиться, что роль добавлена, перейдите на страницу IAM . Созданная вами учётная запись службы должна быть указана вместе с назначенной ей ролью.

5. Понимание подписок по запросу

При подписке по запросу ваша система SAP выступает в роли клиента подписчика и инициирует запросы к серверу Pub/Sub для получения сообщений. Клиент подписчика использует REST Pull API.

Ключевые методы API

API Google Cloud Pub/Sub

• pull: инициирует запрос на извлечение сообщений.
• Подтверждение: сигнализирует Pub/Sub о том, что сообщение успешно обработано.

ABAP SDK для эквивалентов Google Cloud

• /GOOG/CL_PUBSUB_V1 -> PULL_SUBSCRIPTIONS
• /GOOG/CL_PUBSUB_V1 -> ACKNOWLEDGE_SUBSCRIPTIONS

Поток сообщений для подписки по запросу

На следующем рисунке показан рабочий процесс между клиентом-подписчиком и подпиской по запросу.

1. Запрос на извлечение: Ваша система SAP (подписчик) использует метод извлечения для запроса сообщений с сервера Pub/Sub.
2. Ответ на запрос : сервер Pub/Sub отвечает нулём или более сообщений и идентификаторов подтверждения. Ответ с нулём сообщений или ошибкой не обязательно означает, что нет доступных для приёма сообщений. Этот ответ и есть ответ на запрос, как показано на рисунке.
3. Подтверждение: после обработки сообщения ваша система SAP использует метод подтверждения вместе с полученным идентификатором подтверждения. Это предотвращает повторную отправку сообщения службой Pub/Sub.

6. Настройка подписки и отправка сообщений

Создать подписку на рассылку

• Выполните эту команду gcloud, чтобы создать подписку pull с именем PUBSUB_DEMO_SUBSCRIPTION , которая будет получать сообщения из PUBSUB_DEMO_TOPIC :

gcloud pubsub subscriptions create PUBSUB_DEMO_SUBSCRIPTION \
--topic=PUBSUB_DEMO_TOPIC

Опубликовать сообщения

Выберите один из этих методов для отправки сообщений в PUBSUB_DEMO_TOPIC :

• Повторное использование вашей программы: если у вас есть программа из предыдущей лабораторной работы для публикации, используйте ее.
• Прямая публикация : для быстрого теста попробуйте один из следующих вариантов:
• Cloud Console: публикуйте публикации непосредственно в Google Cloud Console. Подробнее см. в документации Pub/Sub .
• Команда gcloud: Выполните следующую команду:

gcloud pubsub topics publish PUBSUB_DEMO_TOPIC \
--message='{"eventType":"SalesOrderChanged","source":"SAPDEV100","eventTime":"20240207183048","SalesOrder":1000924}'

Примечание : при успешной публикации сообщения возвращается идентификатор сообщения.

7. Создайте конфигурацию клиентского ключа.

Теперь, когда вы настроили предварительные условия на стороне Google Cloud, мы можем перейти к настройке на стороне SAP.

Для настройки аутентификации и подключения ABAP SDK для Google Cloud использует таблицы /GOOG/CLIENT_KEY и /GOOG/SERVIC_MAP.

Для сохранения конфигурации в таблице /GOOG/CLIENT_KEY выполните следующие действия:

1. В графическом интерфейсе SAP введите код транзакции SPRO .
2. Нажмите ссылку SAP IMG .
3. Нажмите ABAP SDK для Google Cloud > Основные настройки > Настроить ключ клиента.

4. Введите следующие значения в поля. Остальные поля оставьте пустыми.

Поле	Ценить
Имя ключа Google Cloud	PUBSUB_SUBSCRIBER
Имя учетной записи облачной службы Google	[e-mail]
Область применения Google Cloud	https://www.googleapis.com/auth/cloud-platform
Идентификатор проекта	abap-sdk-poc
Класс авторизации	/GOOG/CL_AUTH_GOOGLE

Примечание : настройка таблицы /GOOG/SERVIC_MAP необязательна и в данном случае может быть пропущена.

8. Создайте отчет ABAP для получения сообщений от Google Cloud Pub/Sub.

1. Войдите в свою систему SAP.
2. Перейдите к коду транзакции SE38 и создайте программу отчета с именем ZDEMO_RECEIVE_CPS_EVENTS.
3. В открывшемся всплывающем окне укажите данные, как показано ниже, и нажмите кнопку Сохранить .

4. В следующем всплывающем окне выберите Локальный объект или укажите имя пакета, если необходимо.
5. В редакторе ABAP добавьте следующий код:

REPORT zdemo_receive_cps_events.

TYPES: BEGIN OF ty_event_message,
         event_time  TYPE timestamp,
         event_type  TYPE char30,
         source      TYPE char30,
         sales_order TYPE vbeln,
       END OF ty_event_message.

DATA: ls_input     TYPE /goog/cl_pubsub_v1=>ty_026,
      ls_input_ack TYPE /goog/cl_pubsub_v1=>ty_001,
      ls_event_msg TYPE ty_event_message.

TRY.

    "Open HTTP Connection
    DATA(lo_client) = NEW /goog/cl_pubsub_v1( iv_key_name = 'PUBSUB_SUBSCRIBER' ).

    "Populate relevant parameters
    " Derive project id from the client object
    DATA(lv_p_projects_id) = CONV string( lo_client->gv_project_id ).
    " Name of the subscription from where we want to pull data
    DATA(lv_p_subscriptions_id) = CONV string( 'PUBSUB_DEMO_SUBSCRIPTION' ).
    " Max number of messages that will be received in 1 API call
    ls_input-max_messages = 1.

    "Call API method: pubsub.projects.subscriptions.pull
    lo_client->pull_subscriptions(
      EXPORTING
        iv_p_projects_id      = lv_p_projects_id
        iv_p_subscriptions_id = lv_p_subscriptions_id
        is_input              = ls_input
      IMPORTING
        es_output             = DATA(ls_output)
        ev_ret_code           = DATA(lv_ret_code)
        ev_err_text           = DATA(lv_err_text)
        es_err_resp           = DATA(ls_err_resp) ).

    IF lo_client->is_success( lv_ret_code ).
      DATA(ls_received_msg) = VALUE #( ls_output-received_messages[ 1 ] OPTIONAL ).
      IF ls_received_msg IS NOT INITIAL.
        "Messages published to Pub/Sub should be base-64 encoded, hence in order to get the exact message, we need to decode the data field.
        "However, attributes published to Pub/Sub should be accessible as data references.
        DATA(lv_msg) = |{ cl_http_utility=>decode_base64( encoded = ls_received_msg-message-data ) }|.
        /ui2/cl_json=>deserialize( EXPORTING json          = lv_msg
                                             pretty_name   = /ui2/cl_json=>pretty_mode-extended
                                   CHANGING  data          = ls_event_msg ).

        cl_demo_output=>new( )->begin_section( |Receive Events from Cloud Pubsub using ABAP SDK for Google Cloud|
        )->write_text( |The below event was successfully received with message ID { ls_received_msg-message-MESSAGE_ID }|
        )->write_data( ls_event_msg
        )->end_section(
        )->display( ).

        ls_input_ack-ack_ids = VALUE #( ( ls_received_msg-ack_id ) ).

        "Call API method: pubsub.projects.subscriptions.acknowledge
        "Acknowledge the messages so it is not pulled again.
        lo_client->acknowledge_subscriptions(
          EXPORTING
            iv_p_projects_id      = lv_p_projects_id
            iv_p_subscriptions_id = lv_p_subscriptions_id
            is_input              = ls_input_ack
          IMPORTING
            es_output             = DATA(ls_output_ack)
            ev_ret_code           = lv_ret_code
            ev_err_text           = lv_err_text
            es_err_resp           = ls_err_resp ).

        IF lo_client->is_success( lv_ret_code ).
          MESSAGE lv_msg TYPE 'S'.
        ELSE.
          MESSAGE lv_err_text TYPE 'E'.
        ENDIF.
      ELSE.
        MESSAGE 'No Messages were received!' TYPE 'S'.
      ENDIF.
    ELSE.
      MESSAGE lv_err_text TYPE 'E'.
    ENDIF.

    "Close HTTP Connection
    lo_client->close( ).

  CATCH /goog/cx_sdk INTO DATA(lo_exception).
    MESSAGE lo_exception->get_text( ) TYPE 'E'.
ENDTRY.

6. Сохраните и активируйте отчет.
7. Выполнить отчет (F8).

При успешном выполнении вы должны увидеть отчет, как показано ниже:

9. Объяснение кода подписчика ABAP Pub/Sub

По сути, эта ABAP-программа интегрируется с Google Cloud Pub/Sub в качестве подписчика на сообщения. Она проверяет указанную подписку на наличие новых сообщений по запросу, обрабатывает их и затем подтверждает получение, чтобы предотвратить повторную доставку в будущем.

В рамках программы будут реализованы следующие мероприятия:

Пошаговое руководство

Установить соединение:

• Он устанавливает HTTP-соединение со службой Google Cloud Pub/Sub, используя класс /GOOG/CL_PUBSUB_V1 .

Установите параметры:

• Идентификатор проекта : извлекает соответствующий идентификатор проекта, в котором находится подписка Pub/Sub.
• Имя подписки: указывает имя подписки, из которой следует извлекать сообщения ( PUBSUB_DEMO_SUBSCRIPTION ).
• Лимит сообщений : устанавливает максимальное количество сообщений, которые можно получить за один вызов API (в данном случае 1).

Извлечь сообщения:

• Вызывает метод pull_subscriptions для извлечения сообщений из указанной подписки.

Обработка полученных сообщений:

• Если сообщения существуют, программа декодирует данные, регистрирует содержимое и отправляет подтверждение.

Подтверждение сообщений:

• Вызывает метод acknowledge_subscriptions для отправки подтверждения Pub/Sub об успешном получении сообщений. Это предотвращает их повторную доставку.

Обработка успешных и ошибочных действий:

• Выводит сообщения об успешном завершении, если сообщения получены и подтверждены, а также сообщения об ошибках для различных сценариев сбоев (сообщения не получены, ошибки API и т. д.).

Тесное соединение:

• Закрывает HTTP-соединение со службой Pub/Sub.

10. Поздравления

Отличная работа по выполнению практической работы «Получение события из Cloud Pub/Sub с использованием ABAP SDK для Google Cloud»!

Вы успешно построили мост между ABAP и Google Cloud Pub/Sub! Выполнение вашей лабораторной работы демонстрирует прочное понимание событийно-управляемого обмена сообщениями и использования ABAP SDK для Google Cloud для интеграции с сервисами Google Cloud. Отлично!

Вы открыли для себя новый уровень интеграции между ABAP и Google Cloud Services. Расширьте свои горизонты с помощью этих интересных возможностей:

• Использование API перевода с ABAP SDK для Google Cloud
• Загрузка большого объекта в контейнер облачного хранилища с использованием фрагментации
• Извлечение учетных данных/секретов из Secret Manager с помощью ABAP SDK для Google Cloud
• Вызовите Vertex AI test-bison из ABAP
• Вызов BigQuery ML из ABAP

11. Уборка

Если вы не хотите продолжать работу с дополнительными практическими занятиями, связанными с ABAP SDK для Google Cloud, пожалуйста, продолжите очистку.

Удалить проект

Внимание : удаление проекта имеет следующие последствия:

• Всё в проекте будет удалено. Если вы использовали существующий проект для задач в этом документе, при его удалении вы также удалите всю остальную работу, выполненную в рамках проекта.
• Пользовательские идентификаторы проектов утеряны. При создании этого проекта вы могли создать собственный идентификатор проекта, который захотите использовать в будущем. Чтобы сохранить URL-адреса, использующие этот идентификатор проекта, например URL-адрес appspot.com , удалите выбранные ресурсы внутри проекта, а не весь проект.

Если вы планируете изучить несколько архитектур, учебных пособий или быстрых стартов, повторное использование проектов может помочь вам избежать превышения квот проекта.

• Удалить проект Google Cloud:

gcloud projects delete abap-sdk-poc

Удалить отдельные ресурсы

1. Удалить вычислительный экземпляр:

gcloud compute instances delete abap-trial-docker

2. Удалить правила брандмауэра:

gcloud compute firewall-rules delete sapmachine

3. Удалить учетную запись службы:

gcloud iam service-accounts delete \
    [e-mail]