एबीएपी SDK टूल के साथ Gemini के एआई का इस्तेमाल करके भावनाओं का विश्लेषण करना

1. परिचय

इस कोडलैब में, आपको Google Cloud के लिए ABAP SDK टूल की मदद से, प्रॉडक्ट की समीक्षाओं पर सेंटीमेंट विश्लेषण करने के लिए, Gemini Pro मॉडल का इस्तेमाल करना होगा. अगर आपका SAP सिस्टम, Compute Engine VM इंस्टेंस पर होस्ट किया गया है, तो हम Google Cloud Vertex AI API को ऐक्सेस करने के लिए, पुष्टि करने की सुविधा सेट अप करने का तरीका बताएंगे. इसके लिए, हम टोकन का इस्तेमाल करेंगे.

इस्तेमाल की गई सेवाओं की सूची:

• Compute Engine
• नेटवर्क सेवाएं
• Cloud Shell
• Vertex AI

आपको क्या बनाना है

आपको ये काम करने होंगे:

• Google API से कनेक्ट करने के लिए, SAP सिस्टम पर इंस्टॉल किए गए ABAP SDK टूल को कॉन्फ़िगर करें.
• Gemini एआई को कॉल करने और प्रॉडक्ट की समीक्षाओं पर सेंटीमेंट का विश्लेषण करने के लिए, रिपोर्ट प्रोग्राम का उदाहरण बनाएं.

2. ज़रूरी शर्तें

• Chrome या Firefox जैसा कोई ब्राउज़र.
• बिलिंग की सुविधा वाला Google Cloud प्रोजेक्ट या Google Cloud Platform के लिए 90 दिनों के मुफ़्त ट्रायल वाला खाता बनाएं.
• आपके सिस्टम में SAP GUI (Windows या Java) इंस्टॉल हो. अगर आपके सिस्टम पर SAP GUI पहले से इंस्टॉल है, तो ऐप्लिकेशन सर्वर आईपी के तौर पर, VM के बाहरी आईपी पते का इस्तेमाल करके SAP से कनेक्ट करें. अगर आपके पास Mac है, तो इस लिंक पर जाकर, Java के लिए SAP GUI इंस्टॉल किया जा सकता है.

3. शुरू करने से पहले

• Google Cloud Console में, प्रोजेक्ट चुनने वाले पेज पर, Google Cloud प्रोजेक्ट चुनें या बनाएं (उदाहरण के लिए: abap-sdk-poc).
• पक्का करें कि आपके Cloud प्रोजेक्ट के लिए बिलिंग की सुविधा चालू हो. किसी प्रोजेक्ट के लिए बिलिंग की सुविधा चालू है या नहीं, यह देखने का तरीका जानें. अगर बिना पैसे चुकाए 90 दिनों के लिए आज़माने वाले खाते का इस्तेमाल किया जा रहा है, तो यह चरण छोड़ दें.
• इसके लिए, आपको Cloud Shell का इस्तेमाल करना होगा. यह Google Cloud में चलने वाला कमांड-लाइन एनवायरमेंट है. Cloud Console में, सबसे ऊपर दाएं कोने में मौजूद Cloud Shell चालू करें पर क्लिक करें:
• 
• पक्का करें कि सभी ज़रूरी एपीआई (AM सेवा खाते के क्रेडेंशियल एपीआई, Vertex AI एपीआई) चालू हों.
• अपने खाते की पुष्टि करने और डिफ़ॉल्ट प्रोजेक्ट को abap-sdk-poc पर सेट करने के लिए, ये कमांड चलाएं. उदाहरण के लिए, ज़ोन us-west4-b का इस्तेमाल किया गया है. अगर ज़रूरी हो, तो अपनी पसंद के हिसाब से नीचे दिए गए निर्देशों में प्रोजेक्ट और ज़ोन बदलें.

gcloud auth login
gcloud config set project abap-sdk-poc
gcloud config set compute/zone us-west4-b
PROJECT_NAME=abap-sdk-poc
REGION=us-west4
ZONE=us-west4-b

• पक्का करें कि आपके पास SAP EPM डेटा के साथ इंस्टॉल किए गए Google Cloud के लिए ABAP SDK टूल वाले SAP सिस्टम का ऐक्सेस हो.
• नया सिस्टम सेट अप करने के लिए, कोडलैब " Google Cloud Platform पर ABAP Platform का ट्रायल वर्शन इंस्टॉल करना और ABAP SDK इंस्टॉल करना" देखें.

4. सेवा खाता बनाना और Vertex AI उपयोगकर्ता की भूमिका सेट करना

1. अगर सेवा खाता पहले से नहीं बनाया गया है, तो उसे बनाने के लिए यह कमांड चलाएं.

gcloud iam service-accounts create abap-sdk-dev \
    --description="ABAP SDK Dev Account" \
    --display-name="ABAP SDK Dev Account"

2. Vertex AI उपयोगकर्ता की भूमिका सेट करने के लिए, यह कमांड चलाएं.

gcloud projects add-iam-policy-binding $PROJECT_NAME \
    --member=serviceAccount:abap-sdk-codelabs@$PROJECT_NAME.iam.gserviceaccount.com \
    --role=roles/aiplatform.user

5. क्लाइंट कुंजी कॉन्फ़िगर करना

SAP सिस्टम में लॉग इन करें. अगर " Google Cloud Platform पर ABAP Platform Trial इंस्टॉल करें और ABAP SDK इंस्टॉल करें" कोडलैब से उपलब्ध कराए गए सिस्टम का इस्तेमाल किया जा रहा है, तो लॉगिन करने के लिए, डिफ़ॉल्ट तौर पर उपलब्ध कराए गए उपयोगकर्ता नाम और पासवर्ड का इस्तेमाल करें.

1. SAP GUI में, ट्रांज़ैक्शन कोड SPRO डालें.
2. SAP रेफ़रंस IMG पर क्लिक करें.
3. Google Cloud के लिए ABAP SDK टूल > बुनियादी सेटिंग > क्लाइंट पासकोड कॉन्फ़िगर करें पर क्लिक करें.
4. नई एंट्री पर क्लिक करें.
5. नीचे दिए गए फ़ील्ड के लिए वैल्यू डालें:

फ़ील्ड	ब्यौरा
Google Cloud की कुंजी का नाम	ABAP_SDK_DEMO
Google Cloud सेवा खाते का नाम	[e-mail]
Google Cloud का दायरा	https://www.googleapis.com/auth/cloud-platform
Google Cloud प्रोजेक्ट आइडेंटिफ़ायर	abap-sdk-poc
अनुमति की कैटगरी	/GOOG/CL_AUTH_GOOGLE.

अन्य फ़ील्ड खाली छोड़ें

6. आरएफ़सी डेस्टिनेशन बनाना

लेन-देन कोड SM59 का इस्तेमाल करके, IAM क्रेडेंशियल और Vertex AI API के लिए आरएफ़सी डेस्टिनेशन बनाएं. अगर ज़रूरी हो, तो आरएफ़सी डेस्टिनेशन बनाने के बारे में ज़्यादा जानने के लिए, कृपया यहां जाएं.

आरएफ़सी डेस्टिनेशन का नाम	टारगेट होस्ट (एपीआई एंडपॉइंट)	नोट
ZGOOG_IAMCREDENTIALS	होस्ट: iamcredentials.googleapis.com पाथ: प्रीफ़िक्स: /v1/ पोर्ट: 443 SSL: चालू है	यह आरएफ़सी डेस्टिनेशन, IAM API को टारगेट करता है.
ZGOOG_VERTEX_AI	होस्ट: us-central1-aiplatform.googleapis.com पोर्ट: 443 SSL: चालू है	यह आरएफ़सी डेस्टिनेशन, Vertex AI API के us-central1 एंडपॉइंट को टारगेट करता है.

• तकनीकी सेटिंग टैब में, ZGOOG_IAMCREDENTIALS डेस्टिनेशन के लिए यह जानकारी डालें.

• तकनीकी सेटिंग टैब में, ZGOOG_VERTEX_AI डेस्टिनेशन के लिए यह जानकारी डालें.

• एसएसएल सर्टिफ़िकेट फ़ील्ड के लिए, पक्का करें कि आरएफ़सी के दोनों डेस्टिनेशन के लिए, डिफ़ॉल्ट एसएसएल क्लाइंट (स्टैंडर्ड) विकल्प चुना गया हो.

7. सेवा मैपिंग कॉन्फ़िगर करना

IAM API और Vertex AI API के लिए, सेवा मैपिंग टेबल को कॉन्फ़िगर करने के लिए, यह तरीका अपनाएं:

1. SAP GUI में, ट्रांज़ैक्शन कोड SPRO डालें.
2. SAP रेफ़रंस IMG पर क्लिक करें.
3. Google Cloud के लिए ABAP SDK टूल > बुनियादी सेटिंग > सेवा मैपिंग कॉन्फ़िगर करें पर क्लिक करें.
4. आईएएम क्रेडेंशियल और Vertex AI API के लिए, नई एंट्री पर क्लिक करें. इसके बाद, आरएफ़सी डेस्टिनेशन को यहां दिखाए गए तरीके से अपडेट करें.

8. कॉन्फ़िगरेशन की पुष्टि करना

पुष्टि करने के कॉन्फ़िगरेशन की पुष्टि करने के लिए, यह तरीका अपनाएं:

1. SAP GUI में, ट्रांज़ैक्शन कोड SPRO डालें.
2. SAP रेफ़रंस IMG पर क्लिक करें.
3. Google Cloud के लिए ABAP SDK टूल > उपयोगिता > पुष्टि करने के लिए पुष्टि करने की सुविधा कॉन्फ़िगरेशन पर क्लिक करें.
4. क्लाइंट पासकोड का नाम ABAP_SDK_DEMO के तौर पर डालें.
5. पूरा फ़्लो सही तरीके से कॉन्फ़िगर हुआ है या नहीं, यह देखने के लिए कार्रवाई करें पर क्लिक करें.
6. नतीजे वाले कॉलम में हरे रंग का सही का निशान दिखने का मतलब है कि कॉन्फ़िगरेशन के सभी चरण पूरे हो गए हैं.

9. प्रॉडक्ट की समीक्षाओं के डेटा का अध्ययन करना

ABAP प्लैटफ़ॉर्म का ट्रायल वर्शन, SAP Enterprise Procurement Model (EPM) के साथ पहले से इंस्टॉल होता है. यह एक ऐसा एंड-टू-एंड ऐप्लिकेशन है जिसे SAP ने डेमो और टेस्टिंग के लिए उपलब्ध कराया है. प्रॉडक्ट की जिन समीक्षाओं का इस्तेमाल सेंटीमेंट विश्लेषण के लिए किया जाएगा उन्हें SNWD_REV_ITEM टेबल में सेव किया जाता है.

टेबल का डेटा देखने के लिए, Tcode: SE16 का इस्तेमाल करें. हम "RATING_TEXT" फ़ील्ड के सैंपल टेक्स्ट का इस्तेमाल करेंगे.

इसके अलावा, Fiori लॉन्चपैड (TCode: /UI2/FLP) से "प्रॉडक्ट मैनेजर" ऐप्लिकेशन को ऐक्सेस करके भी डेटा देखा जा सकता है.

इस स्क्रीनशॉट में प्रॉडक्ट की सूची दिखाई गई है.

प्रॉडक्ट रेटिंग और समीक्षाओं के उदाहरण देखने के लिए, प्रॉडक्ट पर क्लिक करें.

अगले सेक्शन में, हम Google LLM का इस्तेमाल करके सेंटीमेंट का विश्लेषण करने के लिए, प्रॉडक्ट की इन समीक्षाओं के सैंपल का इस्तेमाल करेंगे.

10. Vertex AI Studio का इस्तेमाल करके, भावनाओं का विश्लेषण करना

1. Vertex AI डैशबोर्ड खोलें. इसके बाद, Vertex AI Studio में जाकर भाषा चुनें.
2. नया टेक्स्ट प्रॉम्प्ट बनाएं.

3. Gemini Pro मॉडल को चुनने की पुष्टि करें.
4. एडिटर में, प्रॉडक्ट की समीक्षा में ग्राहक की भावना का विश्लेषण करने के लिए, मॉडल को निर्देश देने के लिए यह प्रॉम्प्ट डालें.
5. मॉडल से जवाब जनरेट करने के लिए, सबमिट करें पर क्लिक करें.

प्रॉम्प्ट:

What's the Customer sentiment in the below product review

Horrible! Unsatisfied in every way! The description is wrong. I sent it back. I want my money back! It is so horrible that I can't even believe it! Too expensive for what I received. I'd expect a little more durability. No instructions included for use or installation. I'm actually really surprised by the positive reviews, which I relied on when ordering. Called customer service..no answer. Looks better than it works. The Worst I have ever seen! Honestly I have no clue what you had in mind when choosing to offer this product. Not sure if I should even post one star.... It broke after 1 day. Poor Quality. Didn't work, that is why I cannot recommend this product.

"SNWD_REV_ITEM" टेबल में मौजूद समीक्षा डेटा का इस्तेमाल, अतिरिक्त प्रॉम्प्ट के साथ मॉडल की जांच करने के लिए किया जा सकता है.

11. Gemini Pro मॉडल को कॉल करने के लिए रिपोर्ट प्रोग्राम बनाना

इस चरण में, हम प्रॉडक्ट की समीक्षाओं का सेंटीमेंट विश्लेषण करने के लिए, ABAP से Gemini Pro मॉडल को कॉल करेंगे. डेमो के मकसद से, प्रोग्राम ज़्यादा से ज़्यादा 10 प्रॉडक्ट की समीक्षाओं को चुनेगा. साथ ही, हर समीक्षा के सेंटीमेंट का पता लगाने के लिए, Gemini Pro मॉडल को कॉल करने के लिए ABAP SDK का इस्तेमाल करेगा. अपने विश्लेषण के आधार पर, मॉडल "पॉज़िटिव", "नेगेटिव", "न्यूट्रल" या "मिक्स" जैसी वैल्यू दिखा सकता है.

1. अपने SAP सिस्टम में लॉग इन करें.
2. ट्रांज़ैक्शन कोड SE38 पर जाएं और ZSENTIMENT_ANALYSIS नाम से रिपोर्ट प्रोग्राम बनाएं.
3. इसके बाद, खुलने वाले पॉप-अप में नीचे दी गई जानकारी दें और सेव करें पर क्लिक करें.

4. अगले पॉप-अप में, लोकल ऑब्जेक्ट चुनें या पैकेज का नाम डालें.

REPORT zsentiment_analysis.

DATA lo_client          TYPE REF TO /goog/cl_aiplatform_v1.
DATA lv_p_projects_id   TYPE string.
DATA lv_p_locations_id  TYPE string.
DATA lv_p_publishers_id TYPE string.
DATA lv_p_models_id     TYPE string.
DATA ls_input           TYPE /goog/cl_aiplatform_v1=>ty_726.
DATA ls_output          TYPE /goog/cl_aiplatform_v1=>ty_727.
DATA lv_ret_code        TYPE i.
DATA lv_err_text        TYPE string.
DATA ls_err_resp        TYPE /goog/err_resp.
DATA lv_msg             TYPE string.
DATA lo_exception       TYPE REF TO /goog/cx_sdk.
DATA es_raw             TYPE string.


TYPES:
  BEGIN OF t_reviews,
    product_id  TYPE snwd_product_id,
    sentiment   TYPE string,
    rating_text TYPE snwd_rating_text,
  END OF t_reviews.

DATA lt_reviews TYPE STANDARD TABLE OF t_reviews WITH DEFAULT KEY.
FIELD-SYMBOLS <fs_review> TYPE t_reviews.

TRY.

    " Open HTTP Connection
    lo_client = NEW #( iv_key_name = 'ABAP_SDK_DEMO' ).

    " Populate relevant parameters
    lv_p_projects_id = lo_client->gv_project_id.
    lv_p_locations_id = 'us-central1'.
    lv_p_publishers_id = 'google'.
    lv_p_models_id = 'gemini-1.0-pro'.

    SELECT a~product_id AS product_id c~rating_text
      FROM ( ( snwd_pd AS a
      INNER JOIN snwd_rev_head AS b ON a~node_key = b~entity_key )
      INNER JOIN snwd_rev_item AS c ON b~node_key = c~parent_key )
      INTO CORRESPONDING FIELDS OF TABLE lt_reviews UP TO 10 ROWS.

    LOOP AT lt_reviews ASSIGNING <fs_review>.

      " Construct the prompt
      DATA(lv_prompt) = |DO NOT EXPLAIN and your response should not have more than one word.| &&
                        |Classify the overall sentiment of this product review as ONLY ONE of| &&
                        | the following: Positive, Negative, Neutral, or Mixed.| &&
                        cl_abap_char_utilities=>newline &&
                        <fs_review>-rating_text.

      " Set the Model Parameters and Prompt
      ls_input = VALUE #( generation_config = VALUE #( max_output_tokens = 10
                                                       temperature       = '0.2'
                                                       top_p             = '0.8'
                                                       top_k             = '40' )
                          contents          = VALUE #( ( role  = 'user'
                                                         parts = VALUE #( ( text = lv_prompt ) ) ) ) ).


      " Call Gemini Pro to identify sentiments.
      lo_client->generate_content_models( EXPORTING iv_p_projects_id   = lv_p_projects_id
                                                    iv_p_locations_id  = lv_p_locations_id
                                                    iv_p_publishers_id = lv_p_publishers_id
                                                    iv_p_models_id     = lv_p_models_id
                                                    is_input           = ls_input
                                          IMPORTING
                                                    es_output          = ls_output
                                                    ev_ret_code        = lv_ret_code
                                                    ev_err_text        = lv_err_text
                                                    es_err_resp        = ls_err_resp ).

      IF lo_client->is_success( lv_ret_code ) = abap_true.

        LOOP AT ls_output-candidates INTO DATA(ls_candidate).
          LOOP AT ls_candidate-content-parts INTO DATA(ls_part).
            <fs_review>-sentiment = ls_part-text.
            EXIT.
          ENDLOOP.
          EXIT.
        ENDLOOP.

      ELSE.
        MESSAGE lv_err_text TYPE 'E'.
      ENDIF.

    ENDLOOP.

    cl_demo_output=>display( lt_reviews ).

    " Close HTTP Connection
    lo_client->close( ).

  CATCH /goog/cx_sdk INTO lo_exception.
    lv_msg = lo_exception->get_text( ).
    MESSAGE lv_msg TYPE 'E'.
ENDTRY.

5. समीक्षा के टेक्स्ट के लिए सेंटीमेंट का विश्लेषण देखने के लिए, प्रोग्राम को चलाएं.

12. बधाई हो

बधाई हो! आपने Google Cloud के लिए ABAP SDK टूल के साथ Gemini Pro एआई का इस्तेमाल करके, सेंटीमेंट विश्लेषण करने के लिए सैंपल प्रोग्राम डेवलप कर लिया है.

13. व्यवस्थित करें

अगर आपको Google Cloud के लिए ABAP SDK टूल से जुड़े अन्य कोडलैब जारी नहीं रखने हैं, तो कृपया क्लीनअप की प्रक्रिया शुरू करें.

प्रोजेक्ट मिटाना

चेतावनी: किसी प्रोजेक्ट को मिटाने पर ये असर होते हैं:

• प्रोजेक्ट में मौजूद सारा कॉन्टेंट मिट जाता है. अगर आपने इस दस्तावेज़ में मौजूद टास्क के लिए किसी मौजूदा प्रोजेक्ट का इस्तेमाल किया है, तो उसे मिटाने पर, प्रोजेक्ट में किया गया आपका सारा काम भी मिट जाएगा.
• कस्टम प्रोजेक्ट आईडी मिट जाते हैं. ऐसा हो सकता है कि इस प्रोजेक्ट को बनाते समय, आपने कोई कस्टम प्रोजेक्ट आईडी बनाया हो. आने वाले समय में, इसका इस्तेमाल किया जा सकता है. प्रोजेक्ट आईडी का इस्तेमाल करने वाले यूआरएल को सुरक्षित रखने के लिए, पूरे प्रोजेक्ट को मिटाने के बजाय, प्रोजेक्ट में चुने गए संसाधनों को मिटाएं. जैसे, appspot.com यूआरएल.

अगर आपको कई आर्किटेक्चर, ट्यूटोरियल या शुरुआती निर्देशों को एक्सप्लोर करना है, तो प्रोजेक्ट का फिर से इस्तेमाल करने से आपको प्रोजेक्ट कोटा की सीमाओं को पार करने से बचने में मदद मिल सकती है.

• Google Cloud प्रोजेक्ट मिटाएं:

gcloud projects delete abap-sdk-poc

अलग-अलग संसाधन मिटाना

1. IMG > Google Cloud > बुनियादी सेटिंग > क्लाइंट पासकोड कॉन्फ़िगर करें पर जाकर, क्लाइंट पासकोड कॉन्फ़िगरेशन की एंट्री मिटाएं.
2. IMG > Google Cloud > बुनियादी सेटिंग > क्लाइंट पासकोड कॉन्फ़िगर करें पर जाकर, सेवा मैपिंग कॉन्फ़िगरेशन की एंट्री मिटाएं.
3. RFC डेस्टिनेशन ZGOOG_IAMCREDENTIALS और ZGOOG_VERTEX_AI मिटाएं.
4. रिपोर्ट प्रोग्राम मिटाएं ZSENTIMENT_ANALYSIS.
5. सेवा खाता मिटाएं.

gcloud iam service-accounts delete \
    [e-mail]